[telkomiot.id] Pengiriman data DHT11 menggunakan modem SIM800 - full AT command

 

Untuk dapat mengikuti praktek yang saya tampilkan ditulisan ini, maka sebelumnya pembaca sebaiknya mengikuti 2 tulisan sebelumnya yaitu :

• Pengiriman data sensor dengan REST API / POST disini 
• Bermain SMS gateway dengan modem simcom disini

Dengan membaca 2 tulisan diatas mungkin dapat memberikan gambaran setup hardware dan perintah-perintah dasar yang akan dipakai terutama AT COMMAND untuk modem simcom yang kali ini akan kita manfaatkan sebagai pengirim data HTTP / POST ke REST API. Daripada bingung, kita coba mengirimkan secara POST menggunakan chrome extension "Talend API Tester" yang dulu pernah sudah dijelaskan pada tulisan sebelumnya. 

Mungkin sedikit akan membingungkan bagi yang tidak terbiasa kirim mengirim teks http, namun saya tekankan gak perlu takut karena yg dikirimkan adalah teks http yang sudah memiliki pola pasti dan tinggal mengikuti saja dan menyesuaikan terutama dibagian authorization credential (access key) dimana pada telkomiot menggunakan accesss:token dengan enkripsi base64.

Sedangkan di level komunikasi modem simcom,  AT Command yg digunakan dulu pernah dibahas ( baca disini ),  dimana secara garis besar urutan untuk modem sim800 terhubung ke network internet 2G/GPRS  adalah sebagai berikut:

void connectToNetwork() {
  sim808.println("AT");
  delay(1000);
  sim808.println("AT+SAPBR=3,1,\"CONTYPE\",\"GPRS\"");
  delay(1000);
  sim808.println("AT+SAPBR=3,1,\"APN\",\"internet\"");
  delay(1000);
  sim808.println("AT+SAPBR=1,1");
  delay(2000);
  sim808.println("AT+SAPBR=2,1");
  delay(1000);
}

Untuk mengecek IP yang diberikan oleh operator, pada function diatas terdapat AT+SAPBR=2,1 , dan jika sudah terkoneksi dengan benar maka kedip dari lampu status modem menjadi lebih cepat sekitar 100ms periodenya. Lalu bagaimana dengan koneksi ke server REST API dan mengirimkan data secara POST? Berikut urutannya :

void sendDataToAPI(String data) {
  // Gabungkan accessKey dan accessToken, lalu encode ke dalam Base64
  String credentials = accessKey + ":" + accessToken;
  String base64Credentials = base64_encode(credentials.c_str());

  sim808.println("AT+HTTPINIT"); // Inisialisasi layanan HTTP
  delay(1000);

  sim808.println("AT+HTTPPARA=\"CID\",1"); // Atur identifikasi konteks ke 1
  delay(1000);

  sim808.println("AT+HTTPPARA=\"URL\",\"" + apiUrl + "\""); // Tentukan URL endpoint API
  delay(1000);

  sim808.println("AT+HTTPPARA=\"CONTENT\",\"application/json\""); // Tentukan tipe konten ke JSON
  delay(1000);

  // Tambahkan header Authorization dengan kredensial yang sudah di-encode Base64
  sim808.println("AT+HTTPPARA=\"USERDATA\",\"Authorization: Basic " + base64Credentials + "\"");
  delay(1000);

  // Persiapkan untuk mengirim data POST beserta panjangnya
  sim808.println("AT+HTTPDATA=" + String(data.length()) + ",10000"); // Tentukan panjang data
  delay(1000);

  sim808.print(data); // Kirim data JSON
  delay(10000); // Tunggu hingga data diunggah

  sim808.println("AT+HTTPACTION=1"); // Eksekusi permintaan HTTP POST (aksi 1 adalah POST)
  delay(5000); // Tunggu respons dari server

  sim808.println("AT+HTTPREAD"); // Baca respons dari server
  delay(1000);
  while (sim808.available()) {
    Serial.write(sim808.read()); // Tampilkan respons untuk debugging
  }

  sim808.println("AT+HTTPTERM"); // Akhiri sesi HTTP
  delay(1000);
}

Penjelasan Masing-Masing Perintah AT

AT+HTTPINIT:

Ini digunakan untuk menginisialisasi layanan HTTP di SIM800. Sebelum melakukan permintaan HTTP (GET atau POST), modem harus dipersiapkan dengan perintah ini.

Respons: OK jika layanan HTTP berhasil diinisialisasi.

AT+HTTPPARA="CID",1:

CID adalah "Context Identifier" yang memberitahu SIM800 koneksi GPRS mana yang akan digunakan. Di sini, CID=1 merujuk pada koneksi GPRS yang diatur dengan AT+SAPBR=1,1 di fungsi connectToNetwork().

Respons: OK jika pengaturan identifikasi konteks berhasil.

AT+HTTPPARA="URL","<your API URL>":

Perintah ini menetapkan URL dari server tempat data akan dikirim. Di sini, Anda memasukkan URL API (http://publish-data.telkomiot.id/v2.0/pubs/...).

Respons: OK jika URL berhasil diatur.

AT+HTTPPARA="CONTENT","application/json":

Perintah ini menentukan tipe konten yang dikirim. Dalam hal ini, Anda mengirim data dalam format JSON, jadi tipe konten diatur ke "application/json".

Respons: OK jika tipe konten berhasil diatur.

AT+HTTPPARA="USERDATA","Authorization: Basic <Base64 credentials>":

Perintah ini menambahkan header kustom ke permintaan HTTP. Di sini, kita menggunakannya untuk menambahkan header Authorization, yang berisi kredensial yang sudah di-encode dalam Base64 (gabungan access_key:access_token). Ini adalah cara standar untuk melakukan autentikasi dengan API.

Respons: OK jika header berhasil ditambahkan.

AT+HTTPDATA=<length>,<timeout>:

Perintah ini mempersiapkan SIM808 untuk menerima data untuk permintaan POST. Parameter <length> menentukan jumlah byte data yang akan dikirim, dan <timeout> adalah waktu (dalam milidetik) yang diizinkan untuk mengirim data. Pada kode di atas, data.length() memberikan panjang payload JSON, dan 10000 (10 detik) diberikan sebagai batas waktu.

Respons: DOWNLOAD jika SIM808 siap menerima data.

sim808.print(data):

Ini mengirim data sebenarnya (payload JSON) ke SIM800 setelah perintah AT+HTTPDATA. Modem sekarang mengetahui berapa banyak data yang akan dikirim dan menunggu dalam periode waktu yang ditentukan.

AT+HTTPACTION=1:

Perintah ini memulai permintaan HTTP POST (1 menandakan POST). SIM800 akan mengirimkan data yang telah disiapkan sebelumnya (dalam format JSON) ke URL yang ditentukan dengan header yang telah ditentukan.

Respons: OK diikuti dengan kode status HTTP, seperti 200 untuk sukses atau 404 untuk tidak ditemukan.

AT+HTTPREAD:

Setelah aksi POST selesai, perintah ini digunakan untuk membaca respons dari server. Respons ini bisa berisi informasi penting, seperti apakah permintaan berhasil.

Respons: Isi tubuh respons HTTP yang dikirim oleh server, ditampilkan di monitor Serial untuk keperluan debugging.

AT+HTTPTERM:

Ini digunakan untuk mengakhiri sesi HTTP dan melepaskan sumber daya yang digunakan oleh SIM800 untuk layanan HTTP. Sebaiknya selalu menutup sesi setelah menyelesaikan permintaan.

Respons: OK jika layanan HTTP berhasil diakhiri.

Dengan kombinasi perintah AT diatas ini, Anda bisa menghubungkan Arduino ke server web (REST API) melalui SIM800, memungkinkan untuk mengirim data sensor ke platform IoT melalui jaringan seluler.

Pada praktek yang sudah saya buat sebelumnya, saya menggunakan sensor DHT11 yang akan memberikan data suhu dan kelembaban dan selanjutnya dikirim ke telkomiot.id secara POST. Pada dashbord serta event trigger bisa disesuaikan dengan keinginan seperti yang telah dibahas pada tulisan sebelumnya. 

Koding Lengkap :

#include <SoftwareSerial.h>
#include <DHT.h>

#define DHTPIN 13      // DHT11 connected to pin 13
#define DHTTYPE DHT11  // DHT 11 sensor type
DHT dht(DHTPIN, DHTTYPE);

SoftwareSerial sim808(2, 3); // RX, TX for SIM800

String apiUrl = "http://publish-data.telkomiot.id/v2.0/pubs/APP111111111/DEV222222222"; //sesuaikan dengan endpoint aplication telkomiot
String accessKey = "11111111111111111";    //sesuaikan dengan akun telkomiot.id
String accessToken = "22222222222222222";

void setup() {
  Serial.begin(9600);
  sim808.begin(9600);
  dht.begin();
  delay(5000); // Give time for SIM800 to initialize

  connectToNetwork();
}

void loop() {
  float h = dht.readHumidity();
  float t = dht.readTemperature();

  if (isnan(h) || isnan(t)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  String postData = "{\"suhu\": \"" + String(t) + "\", \"humi\": \"" + String(h) + "\"}";
  Serial.println(postData);
  sendDataToAPI(postData);
  delay(10000); // Send data every 10 seconds
}

void connectToNetwork() {
  sim808.println("AT");
  delay(1000);
  sim808.println("AT+SAPBR=3,1,\"CONTYPE\",\"GPRS\"");
  delay(1000);
  sim808.println("AT+SAPBR=3,1,\"APN\",\"internet\"");
  delay(1000);
  sim808.println("AT+SAPBR=1,1");
  delay(2000);
  sim808.println("AT+SAPBR=2,1");
  delay(1000);
}

void sendDataToAPI(String data) {
  // Combine accessKey and accessToken, then encode them in Base64
  String credentials = accessKey + ":" + accessToken;
  String base64Credentials = base64_encode(credentials.c_str());

  sim808.println("AT+HTTPINIT");
  delay(1000);
  sim808.println("AT+HTTPPARA=\"CID\",1");
  delay(1000);
  sim808.println("AT+HTTPPARA=\"URL\",\"" + apiUrl + "\"");
  delay(1000);
  sim808.println("AT+HTTPPARA=\"CONTENT\",\"application/json\"");
  delay(1000);

  // Add Authorization header
  sim808.println("AT+HTTPPARA=\"USERDATA\",\"Authorization: Basic " + base64Credentials + "\"");
  delay(1000);

  sim808.println("AT+HTTPDATA=" + String(data.length()) + ",10000");
  delay(1000);
  sim808.print(data);
  delay(10000); // Time to send the data
  
  sim808.println("AT+HTTPACTION=1"); // Start the HTTP POST
  delay(5000);
  
  sim808.println("AT+HTTPREAD");
  delay(1000);
  while (sim808.available()) {
    Serial.write(sim808.read()); // Display response
  }
  
  sim808.println("AT+HTTPTERM"); // End HTTP session
  delay(1000);
}

String base64_encode(const char* input) {
  const char b64_alphabet[] = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/";
  String encoded = "";
  int i = 0, j = 0;
  unsigned char char_array_3[3], char_array_4[4];

  while (*input) {
    char_array_3[i++] = *(input++);
    if (i == 3) {
      char_array_4[0] = (char_array_3[0] & 0xfc) >> 2;
      char_array_4[1] = ((char_array_3[0] & 0x03) << 4) + ((char_array_3[1] & 0xf0) >> 4);
      char_array_4[2] = ((char_array_3[1] & 0x0f) << 2) + ((char_array_3[2] & 0xc0) >> 6);
      char_array_4[3] = char_array_3[2] & 0x3f;

      for (i = 0; i < 4; i++)
        encoded += b64_alphabet[char_array_4[i]];
      i = 0;
    }
  }

  if (i) {
    for (j = i; j < 3; j++)
      char_array_3[j] = '\0';

    char_array_4[0] = (char_array_3[0] & 0xfc) >> 2;
    char_array_4[1] = ((char_array_3[0] & 0x03) << 4) + ((char_array_3[1] & 0xf0) >> 4);
    char_array_4[2] = ((char_array_3[1] & 0x0f) << 2) + ((char_array_3[2] & 0xc0) >> 6);
    char_array_4[3] = char_array_3[2] & 0x3f;

    for (j = 0; j < i + 1; j++)
      encoded += b64_alphabet[char_array_4[j]];

    while ((i++ < 3))
      encoded += '=';
  }

  return encoded;
}

Read More

Membuat SMS Gateway Lucu Dengan SIM800L

 

Sudah lama sekali saya tidak membahas mengenai SMS gateway menggunakan modul sim800, salah satu alasannya mungkin karena ada pemblokiran IMEI dari pemerintah yang menyebabkan beberapa modem menjadi "reject" karena saat diberi AT command "AT+CREG?" balasannya "CREG :0,2" yang artinya reject dari netwoknya. Namun jangan khawatir karena beberapa trik yang dibagikan para penggiat modem simcom ada yg memang cukup jitu, dimana salah satu langkah berikut dapat dilakukan sebelum kamu membuang modem simcom kamu:

1. Pastikan tegangan VCC sesuai yaitu di 3.5-4.2 volt yang merupakan tegangan normal baterai lithium 18650. Jadi jika power supply kamu diatas itu tegangannya maka gunakanlah modul stepdown atau gunakan baterai lithium 18650 + chargernya. Ikuti salah satu setup hardware dibawah :

2. Jika menggunakan modul sim808 atau sim900 yang berupa evaluation board dan sudah ada regulator stepdown, maka pastikan power supply yg masuk ke arduino uno (jika menggandeng 5 voltnya sebagai input power) atau ke modul EV board harus menggunakan adaptor yg amperenya tinggi diatas 1.5A dan diusahakan voltase  adaptor 7.5 volt keatas. Saya menemukan dua kali seperti ini kasus dimana ketika dikasi input tegangan 5 volt modem sim808 saya auto standby / restart saat melakukan registrasi ke network (hanya kedip 4 x saja).

3. Jika memang IMEI dari modem kamu terblok oleh operator, maka langkah terakhir adalah merubah imei dengan perintah "AT+SIMEI=nomer imei baru" . Dimana bisa dapat imei baru ? Ya cari aja hp lawas yang tidak terpakai dan gunakan saja IMEI nya. Saya sukses merubah imei dari sim800L dan jangan sekali kali menghidupkan hp lawas tadi agar server CEIR dari operator seluler tidak mendeteksi fraud imei.

Dan ketika gembira mendapatkan LED modem berkedip per 0.5 detik, atau ketika dicoba "AT+COPS" dibalas "+COPS:0,0,"Indosat" " , maka kamu bisa mencoba script berikut untuk mengirim sms (pastikan pulsanya ada ya !).

#include <SoftwareSerial.h>

#define TX_PIN 8
#define RX_PIN 7

SoftwareSerial serialSIM800(TX_PIN, RX_PIN);

void setup() {
 Serial.begin(9600); //HW Serial Monitor
 while(!Serial);

 Serial.println("Inisialisasi modul SIM800L");
 serialSIM800.begin(9600);
 delay(1000);

 Serial.println("Kirim SMS...");

 //Set mode teks untuk pengiriman sms
 serialSIM800.write("AT+CMGF=1\r\n");
 delay(1000);


//Mulai mengirim Sms ganti nomer tujuan kamu
 serialSIM800.write("AT+CMGS=\"081234567890\"\r\n");
 delay(1000);
 serialSIM800.write("System ready");
 delay(1000);
 serialSIM800.write((char)26); //CTRL-Z
 delay(1000);
 Serial.println("SMS Terkirim!");
}

void loop() {

}

  

Mari kita ingat kembali sekitar 11 tahun lalu saya membagi script untuk melakukan kontrol ke mikrokontroller yang dikirimkan melalui SMS, bisa dibaca disini : https://www.aisi555.com/2013/05/sms-kontrol-mengirim-perintah-ke-micro.html , dan perintah AT commnd yang penting adalah :

AT+CMGF=1  : Untuk merubah ke mode SMS teks

AT+CNMI=2,2 : Untuk merubah sms mode flash sehingga teks bisa langsung diparsing

+CMT :"+628155555555","11/10/01,12 :30 :00+00",
pesan sms disini

AT+CPMS =?  : ini bisa diubah untuk memilih penyimpanan sms, lakukan di luar koding

AT+CMGD=1,4 : Delete semua sms agar tidak gagal sms yg baru masuk

 

Tujuan saya pada tulisan ini adalah untuk membuat semacam gateway sms humor yang akan kemudian dicoba didepan kelas mikrokontroler di prodi teknik listrik vokasi Unesa Surabaya. Jadi para mahasiswa akan mengirim sms nama mereka ke nomer sim808 yang saya pakai untuk kemudian di balas berupa humor bapack-bapack yang lumayan garing namun seru.

Bagaimana scriptnya ? Ini lengkapnya :

#include <SoftwareSerial.h>
#include <avr/pgmspace.h>  // untuk menghemat RAM gunakan PROGMEM

SoftwareSerial gsm(2, 3);  // RX, TX pins ke modem
String message = "";
String senderNumber = "";  // variabel nomer yang akan dibalas
bool newMessage = false;   // Flag ada pesan baru

// jokes bapak bapak disimpan di PROGMEM
const char joke1[] PROGMEM = "Kenapa ayam nyebrang jalan? Karena mau ke seberang!";
const char joke2[] PROGMEM = "Kenapa gajah bawa koper? Karena mau pergi liburan!";
const char joke3[] PROGMEM = "Kenapa Indonesia panas banget ya? Padahal negara ASEAN.";
const char joke4[] PROGMEM = "Uang 100 ribu jika dilempar bakal jadi apa? Jadi rebutan.";
const char joke5[] PROGMEM = "Apa yang lebih besar dari dinosaurus? Hutan tempat mereka tinggal.";
const char joke6[] PROGMEM = "Huruf-huruf apa yang sering kedinginan? Huruf B karena ada di tengah-tengah AC.";
const char joke7[] PROGMEM = "Kentang apa yang bisa bikin bayi ketawa? Kentang-tingtung-tingtang-tingtungtang.";
const char joke8[] PROGMEM = "Kesenian apa yang sering dilakukan nasabah bank? Tari tunai.";
const char joke9[] PROGMEM = "Sapi apa yang larinya cepat? Sapida motor.";
const char joke10[] PROGMEM = "Monyet apa yang bikin sebel? Monyetel tivi nggak ada remote.";
const char joke11[] PROGMEM = "Sepeda apa yang tak bisa dicat? Sepeda hilang.";

const char* const jokes[] PROGMEM = {joke1, joke2, joke3, joke4, joke5, joke6, joke7, joke8, joke9, joke10, joke11};  // Array of joke pointers

void setup() {
  gsm.begin(9600);  // Start GSM communication
  Serial.begin(9600);  // For serial monitor
  delay(1000);
  Serial.println("Test GSM Modem Server for UNESA");
  // Initialize GSM modem
  gsm.println("ATE1");
  delay(1000);
  gsm.println("AT+CMGF=1");  // Set text mode
  delay(1000);
  gsm.println("AT+CNMI=2,2");  // Sms langsung baca
  delay(1000);
  gsm.println("AT+CMGD=31,4");  // Hapus sms
  delay(1000); 

}

void loop() {
  if (gsm.available()) {
    char c = gsm.read();
    message += c;

    if (c == '\n') {  // End of a line
      Serial.print("Received: ");
      Serial.println(message);

      // Check for SMS header (+CMT) to know it's an incoming message
      if (message.indexOf("+CMT") != -1) {
        senderNumber = extractPhoneNumber(message);  // Extract sender's number
        newMessage = true;  // Set flag indicating the next line will be the message body
      } 
      else if (newMessage && message.length() > 1) {  // Process the next line after +CMT as the message body
        String studentName = message;
        studentName.trim();  // Remove any trailing spaces or newlines

        // Send greeting with a random joke
        String reply = createReply(studentName);
        sendSMS(senderNumber, reply);  // Use senderNumber extracted earlier
        newMessage = false;  // Reset flag after sending the SMS
      }

      message = "";  // Clear the message for the next line
    }
  }
}

// Extract phone number from the +CMT line
String extractPhoneNumber(String msg) {
  int startIndex = msg.indexOf("\"") + 1;
  int endIndex = msg.indexOf("\"", startIndex);
  return msg.substring(startIndex, endIndex);
}

// Create the reply message with a greeting and a random joke
String createReply(String name) {
  String greeting = "Halo " + name + ", ";

  // Generate a random index and fetch the joke from PROGMEM
  int randomIndex = random(0, 11);  
  char joke[100];  // Create a buffer to store the joke
  strcpy_P(joke, (char*)pgm_read_word(&(jokes[randomIndex])));  // Read the joke from PROGMEM
  
  return greeting + String(joke);  // Combine greeting with joke
}

// Function to send an SMS
void sendSMS(String phoneNumber, String message) {
  gsm.println("AT+CMGS=\"" + phoneNumber + "\"\r");  // Send the AT command for the recipient's number
  delay(100);
  gsm.print(message);  // Send the SMS body
  delay(100);
  gsm.write(26);  // Send Ctrl+Z to end the SMS
  delay(500);
}

BREAKDOWN :

Yang paling penting adalah meng-extract nomer pengirim dan nama pengirim SMS saat ada pesan masuk dari uart modem berupa string "+CMT " :

if (gsm.available()) {
    char c = gsm.read();
    message += c;

    if (c == '\n') {  // End of a line
      Serial.print("Received: ");
      Serial.println(message);

      // Check for SMS header (+CMT) to know it's an incoming message
      if (message.indexOf("+CMT") != -1) {
        senderNumber = extractPhoneNumber(message);  // Extract sender's number
        newMessage = true;  // Set flag indicating the next line will be the message body
      } 
      else if (newMessage && message.length() > 1) {  // Process the next line after +CMT as the message body
        String studentName = message;
        studentName.trim();  // Remove any trailing spaces or newlines

        // Send greeting with a random joke
        String reply = createReply(studentName);
        sendSMS(senderNumber, reply);  // Use senderNumber extracted earlier
        newMessage = false;  // Reset flag after sending the SMS
      }

      message = "";  // Clear the message for the next line
    }
  }

Ekstraksinya ada di function ini :

// Extract phone number from the +CMT line
String extractPhoneNumber(String msg) {
  int startIndex = msg.indexOf("\"") + 1;
  int endIndex = msg.indexOf("\"", startIndex);
  return msg.substring(startIndex, endIndex);
}

Selanjutnya adalah pemilihan jokes bapack-bapack secara random serta ditambahkan nama pengirim. Disini dapat dilihat terdapat perintah random dan diarahkan ke array jokes[] di PROGMEM

// Create the reply message with a greeting and a random joke
String createReply(String name) {
  String greeting = "Halo " + name + ", ";

  // Generate a random index and fetch the joke from PROGMEM
  int randomIndex = random(0, 11);  
  char joke[100];  // Create a buffer to store the joke
  strcpy_P(joke, (char*)pgm_read_word(&(jokes[randomIndex])));  // Read the joke from PROGMEM
  
  return greeting + String(joke);  // Combine greeting with joke
}

Lalu kemudian SMS dikirim kembali.

// Function to send an SMS
void sendSMS(String phoneNumber, String message) {
  gsm.println("AT+CMGS=\"" + phoneNumber + "\"\r");  // Send the AT command for the recipient's number
  delay(100);
  gsm.print(message);  // Send the SMS body
  delay(100);
  gsm.write(26);  // Send Ctrl+Z to end the SMS
  delay(500);
}

Dan hasilnya bisa dilihat pada gambar yang paling atas. SMS gateway seperti ini dulunya banyak digunakan untuk server penjual pulsa dimana pada saat pembelian pulsa maka dikirmkan kode-kode pulsa melalui sms ke nomer gatewaynya, dan kalau kalian sempat melihat voting indonesian idol jadul dibawah tahun 2010an maka votingnya dilakukan menggunakan sms gateway seperti penjelasan saya diatas.

Read More

[telkomiot.id] Pengolahan Data Lorawan Menjadi Grafik Dengan Python

 

Setelah berhasil menggunakan API dengan benar pada tulisan sebelumnya, kini saya lanjutkan pengolahan data yang dikirimkan menggunakan LoRaWan pada telkomIOT. Alat yang saya gunakan masih yang lama ketika 3 tahun lalu berkenalan dengan lorawan yaitu hardware mikrokontroler berbasis arduino nano dengan modul lora sx1276 - 915Mhz.

Jadi jika pembaca baru berkenalan dengan lorawan, silahkan baca dulu klik disini karena scriptnya masih sama hanya beda di authentifikasi lorawannya saja kini menuju ke telkomiot. Dan juga yang mencolok adalah antenanya yaitu setelah saya dan anak-anak magang serta tugas akhir dari Unesa Surabaya - prodi D4 teknik listrik berhasil meneliti antena dipole + yagi sederhana (pake antena tv) sebagai pengirim sinyal lebih baik (baca disini). Hasilnya kini dalam rumah yang dulunya sangat susah kirim data akibat pembangunan gedung tinggi di sebelah rumah, kini dapat mengirimkan dengan lancar sekali

Dan sesuai contoh di tulisan sebelumnya maka dapat diolah data yang diterima menjadi widget seperti gambar dibawah ini.

Untuk pengolahan data diluar telkomiot sayangnya tidak bisa terlalu realtime dikarenakan mqtt yang belum jalan, yang disediakan hanya berupa REST API secara GET yang dinamakan API Integration seperti gambar dibawah.

Dan kalau kita coba pada postman atau Talend API Tester hasilnya berupa 10 data terakhir dari data lorawan yang berhasil di UPLINK ke database telkomiot.

Karena datanya berjumlah 10 maka sangat terbantu untuk membuat grafik menggunakan platform apapun baik java (node.js), php atau kesukaan saya menggunakan python seperti script berikut ini:

# Script Untuk Mengambil Data Lorawan TelkomIot
# by Nyoman yudi - www.aisi555.com
# ahocool@gmail.com  08155737755


import requests
import json
import base64
import matplotlib.pyplot as plt
import matplotlib.animation as animation
from dateutil import parser
from datetime import datetime
import signal
import sys

# Telkom IoT API details , sesuaikan
API_URL = 'https://api-data.telkomiot.id/api/v2.0/APPxxxxxxxxxxxxx/DEVxxxxxxxxxxxx/lasthistory'
ACCESS_KEY = 'aaaaaaaaaaaaaaaa'
TOKEN_KEY = 'bbbbbbbbbbbnnnnnn'

# Encode accesskey:tokenkey to Base64
auth_string = f'{ACCESS_KEY}:{TOKEN_KEY}'
auth_bytes = auth_string.encode('utf-8')
auth_base64 = base64.b64encode(auth_bytes).decode('utf-8')

HEADERS = {
    'Authorization': f'Basic {auth_base64}',
    'Content-Type': 'application/json'
}

# Lists to store timestamps, temperature, and humidity data
timestamps = []
temperature_data = []
humidity_data = []

# Function to fetch data from Telkom IoT API
def fetch_data():
    try:
        response = requests.get(API_URL, headers=HEADERS)
        if response.status_code == 200:
            data = response.json()
            timestamps.clear()
            temperature_data.clear()
            humidity_data.clear()
            for entry in data:
                timestamp = parser.isoparse(entry['time'])
                sensor_data = json.loads(entry['data'])
                temperature = sensor_data['suhu']
                humidity = sensor_data['humi']
                timestamps.append(timestamp)
                temperature_data.append(temperature)
                humidity_data.append(humidity)
        else:
            print(f"Failed to fetch data: {response.status_code}")
    except Exception as e:
        print(f"Error fetching data: {e}")


# Function to update the graph
def update_graph(i):
    fetch_data()
    ax.clear()
    width = 0.4  # Width of the bars
    indices = range(len(timestamps))

    # Create bars for temperature and humidity
    bars1 = ax.bar([x - width / 2 for x in indices], temperature_data, width, label='Temperature (°C)')
    bars2 = ax.bar([x + width / 2 for x in indices], humidity_data, width, label='Humidity (%)')

    # Set the labels
    ax.set_xlabel('Time')
    ax.set_ylabel('Value')
    ax.set_xticks(indices)
    ax.set_xticklabels([ts.strftime('%H:%M:%S') for ts in timestamps], rotation=45)
    ax.legend(loc='upper left')


# Function to handle graceful shutdown
def signal_handler(sig, frame):
    print('Stopping the script...')
    sys.exit(0)


# Set up the plot
fig, ax = plt.subplots()

# Animate the plot
ani = animation.FuncAnimation(fig, update_graph, interval=10000, cache_frame_data=False)  # Update every 10 seconds

# Register the signal handler
signal.signal(signal.SIGINT, signal_handler)

# Display the plot
plt.show()

Dan hasilnya cukup dapat dihandalkan lhooo....

Read More

[telkomiot.id] Mengirim Data DHT11 - ESP8266 via REST API dan Menampilkan di Widget & Notif Ke Email

 

Walau sempat galau karena MQTT gagal dikirimkan ke platform Telkomiot.id, tidak usah nyinyir berlebihan karena ada satu cara yang umum dilakukan untuk kirim-terima data yaitu via REST API / HTTP/ POST . Langsung aja yuk kita mencoba menggunakan software semacam postman untuk mengirimkan data secara HTTP, dan saya pilihkan yang lebih mudah yaitu chrome extension bernama "Talend API Tester". Langkah-langkahnya cukup straight forward, kita cek dulu alamat endpoint dari REST API nya pada console :application/device di website telkomiot.

Sesuai petunjuk bapak presiden...ehhh salah..dokumentasi yang sangat sedikit, saya menerka bahwa akan ada authentification /authorization berdasarkan access key dan token key untuk access  api dan biasanya ditambahkan pada header berupa "authorization". Lanjutkan aja dengan memasukkan pasangan key yang benar

Header yang gak kalah penting adalah "Content-Type" : "application/json" dan langsung saja saya coba dan berhasil mengirimkan data suhu dan humi ke telkomiot....yeahhh

Bagaimana dengan mengirimkan secara hardware? saya pilihkan microcontroller + sensor sejuta umat paling murah meriah : Wemos + DHT11.

Bagi yang masih awam dengan wemos/esp8266 untuk mengukur suhu dengan DHT11, dapat belajar dulu seri tulisan IOT yang full menggunakan rangkaian seperti diatas ( baca dulu klik disini )

*/telkomiot.id testing from www.aisi555.com
  by nyoman yudi kurniawan ahocool@gmail.com
  08155737755 - surabaya 2024
*/
#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>
#include <WiFiClient.h>
#include "DHT.h"
#include <base64.h>

// wifi kamu sesuaikan
const char* ssid = "hotspothp";
const char* password = "tanyasebelah";

// Domain http publish dari device DHT11 ditelkomiot, sesuaikan
const char* serverName = "http://publish-data.telkomiot.id/v2.0/pubs/APP1111111111/DEV222222222223";

// account key dari telkomiot
String AccessKey   = "aaaaaaaaaaaaaaaa";
String AccessToken = "bbbbbbbbbbbbbbbb";
String auth;
String authHeader;

const int dhtPin = D3; //Sesuaikan pin DHT
#define DHTTYPE DHT11  //Sensor DHT11
DHT dht(dhtPin, DHTTYPE); 

//timer untuk membaca DHT11 tiap 10 detik
unsigned long lastTime = 0;
unsigned long timerDelay = 10000;

WiFiClient client;
HTTPClient http;

void setup() {
  Serial.begin(9600);
  delay(1000);
  Serial.println("www.aisi555.com ==> telkomiot.id testing");
  WiFi.begin(ssid, password);
  Serial.println("Connecting");
  while(WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Terhubung wifi : ");
  Serial.print(ssid);
  Serial.print("  IP : ");
  Serial.println(WiFi.localIP());


   //auth header untuk POST
  auth = AccessKey+ ":" + AccessToken;
  authHeader = "Basic " + base64::encode(auth);
 
}

String SendTempHumid(){ // pengukuran DHT
   
 
    float h = dht.readHumidity();
    float t = dht.readTemperature();

    if (isnan(h) || isnan(t)) {
      Serial.println("Failed to read from DHT sensor!");
    }
    
    Serial.print("Humidity: "); 
    Serial.print(h);
    Serial.print(" %\t");
    Serial.print("Temperature: "); 
    Serial.print(t);
    Serial.println(" °C ");
  //yang dikirim data berupa string JSON
  
  return( "{\"suhu\":" + String(t) + ",\"humi\":" + String(h) +"}"); 
  }


void loop() {
  //Send HTTP POST request tiap 10 detik
  if ((millis() - lastTime) > timerDelay) {
    //Check WiFi connection status
    if(WiFi.status()== WL_CONNECTED){

      
      // server untuk kirim REST API
      http.begin(client, serverName);
      
      // Specify content-type header
      http.addHeader("Authorization", authHeader);
      http.addHeader("Content-Type", "application/json");
      // Data to send with HTTP POST
      String httpRequestData = SendTempHumid();           
      // Send HTTP POST request
      int httpResponseCode = http.POST(httpRequestData);
      

      Serial.print("HTTP Response code: ");
      Serial.println(httpResponseCode);
        
      // Free resources
      http.end();
    }
    else {
      Serial.println("WiFi terputus");
    }
    lastTime = millis();
  }
}

Hasilnya bagaimana  ?

Penjabarannya seperti berikut :

Library :

#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>
#include <WiFiClient.h>
#include "DHT.h"
#include <base64.h>

Yang digunakan library standar ESP8266 untuk kirim terima data via http dan sudah tersedia semua secara default. Yang mungkin berbeda adalah base64.h yang jarang digunakan, kali ini tujuannya untuk meng-enkripsi auth key sebagai standar auth pada REST API.

Rest API endpoint + auth:

// Domain http publish dari device DHT11 ditelkomiot, sesuaikan
const char* serverName = "http://publish-data.telkomiot.id/v2.0/pubs/APP1111111111111111/DEV222222222222222";

// account key dari telkomiot
String AccessKey   = "aaaaaaaaaaaaaaaa";
String AccessToken = "bbbbbbbbbbbbbbbb";
String auth;
String authHeader;

WiFiClient client;
HTTPClient http;

Base 64 auth Header :

   //auth header untuk POST
  auth = AccessKey+ ":" + AccessToken;
  authHeader = "Basic " + base64::encode(auth);

Baca DHT 11 :

String SendTempHumid(){ // pengukuran DHT
   
 
    float h = dht.readHumidity();
    float t = dht.readTemperature();

    if (isnan(h) || isnan(t)) {
      Serial.println("Failed to read from DHT sensor!");
    }
    
    Serial.print("Humidity: "); 
    Serial.print(h);
    Serial.print(" %\t");
    Serial.print("Temperature: "); 
    Serial.print(t);
    Serial.println(" °C ");
  //yang dikirim data berupa string JSON
  
  return( "{\"suhu\":" + String(t) + ",\"humi\":" + String(h) +"}"); 
  }

Kirim secara post :

      // server untuk kirim REST API
      http.begin(client, serverName);
      
      // Specify content-type header
      http.addHeader("Authorization", authHeader);
      http.addHeader("Content-Type", "application/json");
      // Data to send with HTTP POST
      String httpRequestData = SendTempHumid();           
      // Send HTTP POST request
      int httpResponseCode = http.POST(httpRequestData);
      

      Serial.print("HTTP Response code: ");
      Serial.println(httpResponseCode);
        
      // Free resources
      http.end();

Lumayan straight forward, hanya meniru apa yang sudah dilakukan pada aplikasi testing REST API sebelumnya, dan jika data json / dht11 benar maka pada monitor terminal muncul ini.

Http response 200 artinya data diterima dengan benar, sedangkan jika 400 berarti json pengambilan data dht11 nya salah.

Lalu bagaimana cara menampilkan gauge dan grafik seperti gambar paling diatas? tinggal menuju menu personal dashboard , lalu buat dashboard kamu serta tambahkan widget yang dihubungkan ke device kamu.

Dan jika benar, maka akan muncul widget berupa gauge-line chart-bar chart sesuai yang kamu pilih. Dan tiap widget ini dapat ditempelkan pada website kamu lhoo..

Dan bisa kirim alarm lewat  event trigger ke email lhooo ...

Walau kekecewaan masih tersirat pada saya yang pencinta MQTT ini, namun dengan praktek diatas agak sedikit terobati, dan semoga kalian bisa mencobanya sendiri

Read More