Modifikasi Mobil - Mobilan RC 27Mhz Menjadi Berbasis WiFi

 

Tulisan kali ini sebenarnya masih ada hubungannya dengan kerjasama saya Bersama Fakultas Vokasi Unesa dalam hal penelitian dibidang Transportasi. Gaya nya sih pengen membuat robot AGV seperti di gudang nya amazon sana yang banyak bertebaran videonya di medsos, namun seperti biasa kita mainan yang kecil-kecilan dulu. Yuk kita utak-atik mobil-mobilan RC Truk seharga 100ribuan dulu. Sekalian mau melihat bagaimana sih kontrol yang didalamnya ?

Truk mainan Remote diatas sangat umum di toko mainan bahkan mungkin hampir dimiliki oleh semua anak kecil (cowok) karena hemat saya lebih mengajarkan kegiatan outdoor ke anak daripada berkutat dengan smartphone melulu. Namun setelah saya perhatikan jangkauan kendali remotenya cukup pendek sehingga otomatis ketika diatas 5 meter gak akan nyampai tuh kendalinya. Menjadi keheranan saya kenapa sependek itu? Apakah agar anak ikutan berlari dibelakang mobil-mobilan? Namun secara teknis ini terjadi karena ketika saya bongkar antena di dalam kontroler disisi mobil-mobilannya hanya berupa kabel saja. Harus dikasi tambahan apa ya agar jauh?

Gambar diatas merupakan modul kontroler yang dapat dibeli di berbagai onlineshop (bahkan sepaket dengan motor DC nya) hanya 25 ribu saja (dapet untung dari mana coba produsennya ...ckckckckc). Dari berbagai tulisan dan video di internet rata-rata yang dilakukan adalah menambahkan antena dan jangkauannya gak jauh juga. Nah bagaimana dengan memanfaatkan wifi dirumah yang lumayan jauh jangkauannya ? Kita bisa gunakan bantuan mikrokontrolelr ber wifi macam ESP8266/ESP32.

Prinsipnya sebagai berikut:

1. Gunakan relay 5V atau transistor sebagai penyambung tombol yang ada pada modul remote, kemudian di kontrol oleh pin dari ESP32. Saya lebih memilih transistor kebetulan ada banyak transistor PNP 2N3906 di gudang sehingga hanya butuh tambahan resistor 1K ke basis dan kontrol logika aktif LOW untuk menyambungkan tombol switch. Ilustrasinya seperti berikut : 

2. ESP32 terhubung dengan wifi rumah dan menggunakan komunikasi UDP / TCP sebagai protokol pengiriman data. Perintah yg dikirim berupa teks "1" untuk maju, "2" untuk mundur, "3" belok kiri, "4" belok kanan dan "0" untuk stop.

3. Untuk kontrol jarak jauh (kanan kiri maju mundur) bisa menggunakan aplikasi smartphone android UDP terminal, seperti pada gambar paling atas. Saya ada juga koding APK sendiri namun saya bahas lain waktu. 

4. Remote dapat di bongkar menyisakan PCB nya saja dan taruh  bersama ESP32 diatas / didalam back truk. Jangan lupa menambahkan Power suply berupa powerbank agar dapat mensuply ESP32 dan juga modul remote. 

5. Saya menyambungkan pin 3.3 Volt dari ESP32 ke pin baterai + dari modul remote. 

Koding di ESP32 :

#include <WiFi.h>
#include <WiFiUdp.h>

// Konfigurasi WiFi sesuaikan
const char* ssid = "nama wifi";
const char* password = "paswordnya";

// IP statis sesuaikan, agar tidak berubah ubah
IPAddress ip(192, 168, 1, 177);
IPAddress gateway(192, 168, 1, 1);     // samakan IP router yg digunakan
IPAddress subnet(255, 255, 255, 0);

// Port UDP nya bebas
unsigned int udpPort = 4210;
WiFiUDP udp;

// Sinyal ke Transistor sesuaikan dengan pin di ESP32 yg kamu pakai
#define MAJU_PIN    15
#define MUNDUR_PIN   2
#define KANAN_PIN    4
#define KIRI_PIN     5

void setup() {
  // Inisialisasi pin sebagai output
  pinMode(MAJU_PIN, OUTPUT);
  pinMode(MUNDUR_PIN, OUTPUT);
  pinMode(KANAN_PIN, OUTPUT);
  pinMode(KIRI_PIN, OUTPUT);

  // Set awal semua pin HIGH (non-aktif karena aktif LOW)
  digitalWrite(MAJU_PIN, HIGH);
  digitalWrite(MUNDUR_PIN, HIGH);
  digitalWrite(KANAN_PIN, HIGH);
  digitalWrite(KIRI_PIN, HIGH);

  // Mulai koneksi WiFi dengan IP statis
  WiFi.config(ip, gateway, subnet);
  WiFi.begin(ssid, password);

  Serial.begin(115200);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("\nKoneksi WiFi berhasil");
  Serial.print("IP Address: ");
  Serial.println(WiFi.localIP());

  // Mulai UDP
  udp.begin(udpPort);
  Serial.printf("Listening on UDP port %d\n", udpPort);
}

void maju()
{

    digitalWrite(MAJU_PIN, LOW );
    digitalWrite(MUNDUR_PIN, HIGH);
    digitalWrite(KANAN_PIN, HIGH);
    digitalWrite(KIRI_PIN, HIGH);

  Serial.println("ini maju ...");
}

void mundur()
{

    digitalWrite(MAJU_PIN, HIGH );
    digitalWrite(MUNDUR_PIN, LOW);
    digitalWrite(KANAN_PIN, HIGH);
    digitalWrite(KIRI_PIN, HIGH);

    Serial.println("ini mundur ...");

}

void kiri()
{

    digitalWrite(MAJU_PIN, LOW);
    digitalWrite(MUNDUR_PIN, HIGH);
    digitalWrite(KANAN_PIN, HIGH);
    digitalWrite(KIRI_PIN, LOW);


    Serial.println("ini ngiri ...");
  
}

void kanan()
{

    digitalWrite(MAJU_PIN, LOW );
    digitalWrite(MUNDUR_PIN, HIGH);
    digitalWrite(KANAN_PIN, LOW);
    digitalWrite(KIRI_PIN, HIGH);

    Serial.println("ini nganan ...");
}

void mandek()
{

    digitalWrite(MAJU_PIN, HIGH);
    digitalWrite(MUNDUR_PIN, HIGH);
    digitalWrite(KANAN_PIN, HIGH);
    digitalWrite(KIRI_PIN, HIGH);

    Serial.println("ini mandek ...");
}

void loop() {


  char packetBuffer[255]; // Buffer untuk menerima data UDP

  // Cek apakah ada paket UDP masuk
  int packetSize = udp.parsePacket();
  if (packetSize) {
    int len = udp.read(packetBuffer, 255);
    if (len > 0) {
      packetBuffer[len] = '\0'; // Null-terminate string
    }

    Serial.printf("Pesan diterima: %s\n", packetBuffer);

    // Proses perintah 1=maju 2=mundur 3=kiri 4=kanan 0=stop , silahkan berkreasi untuk model pergerakan sesuai yg anda mau
    if (strcmp(packetBuffer, "1") == 0) {
      maju();
      delay(600);
      mundur();
      delay(200);
      mandek();
      
    } else if (strcmp(packetBuffer, "2") == 0) {
      mundur();
      delay(600);
      maju();
      delay(200);
      mandek();
    } else if (strcmp(packetBuffer, "3") == 0) {
      kiri();
      delay(700);
      mundur();
      delay(150);   
      mandek();
    } else if (strcmp(packetBuffer, "4") == 0) {
      kanan();
      delay(700);
      mundur();
      delay(150);   
      mandek();
    } else if (strcmp(packetBuffer, "0") == 0) {
      // Semua tetap HIGH → berhenti total
      mandek();
      Serial.println("Perintah BERHENTI diterima");
    }

    
  }
  
}

SELAMAT MENCOBA !

Read More

Grafik IOT Dynamic dengan Webhook - GoogleSheets - Google Apps Script

 

Semakin hari layanan internet web "gratis" semacam google berlomba menyajikan kemudahan bagi penggunanya, seperti saya yang kebetulan sedang mencari cara menampilkan grafik IOT secara dinamic. Pada platform IOT semacam antares / telkomiot bisa memanfaatkan fasilitas widget grafik dan pernah juga saya bahas menggunakan webhook pada antares (baca disini). Namun teringat saya pada request seorang mahasiswa yang kesulitan melakukan embeeded / tempel grafiknya di laporan tugas akhirnya dan pada waktu itu saya pake jembatan di google collab untuk menampilkan grafik di quickchart.io. 

Lalu gambar grafik iot diatas kok bisa dinamis dan interaktif begitu ? Mari saya kasi tau caranya ..

Pertama kita butuh mikrokontroler untuk mengirimkan data atau bisa juga gunakan simulator saja dan yang saya pilihkan bernama wokwi yang sudah sering dibahas di blog ini. Jadi kita akan membuat simulator pengirim data tegangan dan arus (secara random) yang bisa dibuka pada link wokwi disini.

Script nya akan mengirim data secara POST menuju alamat endpoint webhooks dan format datanya berupa JSON. Untuk mengetest apakah data terkirim dengan benar dapat menggunakan tester webhooks / POST online bernama requestcatcher seperti pada gambar berikut :

Lalu kita lanjutkan mengirimkan weebhook ke Google sheets seperti yang saya tulis terdahulu (baca disini) menggunakan antares, dan kini tanpa antares langsung dari ESP32 menuju googlesheets dan hasilnya tiap item pada JSON akan di tambahkan ke baris baru kebawah terus menerus jika ada data baru yg masuk.

Lalu bagaimana caranya membuat agar datanya hanya dibatasi 20 data terakhir sehingga grafiknya dapat lebih mudah dilihat ? Ternyata googlesheets memiliki fasilitas APPS SCRIPTS yang bisa menjadi coding otomasi dari webhooks ke googlesheets. Secara default maka apps scripts yang disediakan adalah berhubungan dengan webhooks, namun kita bisa hapus dan kemudian kreasikan sendiri (thanks to chatgpt).

 

Script yang saya tambahkan seperti berikut

function doPost(e) {

  try {

    if (!e || !e.postData) {

      throw new Error("No postData received. Check the incoming request.");

    }

   

    // Log the raw data for debugging

    Logger.log(e.postData.contents);

    // Parse the incoming JSON data

    var jsonData = JSON.parse(e.postData.contents);

   

    // Extract voltage and current from the JSON payload

    var voltage = jsonData.volt || "N/A";  // Default to "N/A" if missing

    var current = jsonData.amp || "N/A";  // Default to "N/A" if missing

    var timestamp = new Date().toISOString(); // Get the current timestamp

   

    // Get the active sheet and append the data as a new row

    var sheet = SpreadsheetApp.getActiveSpreadsheet().getActiveSheet();

    sheet.appendRow([timestamp, voltage, current]);

   

    // Keep only the last 20 rows (delete older rows if necessary)

    var lastRow = sheet.getLastRow();

    if (lastRow > 21) { // Keep the header row

      sheet.deleteRow(2); // Always delete the second row (keep header row intact)

    }

   

    return ContentService.createTextOutput("Data added to Google Sheets");

  } catch (error) {

    // Log the error for debugging

    Logger.log("Error: " + error.message);

    return ContentService.createTextOutput("Error: " + error.message);

  }

}

Dan kemudian hasilnya grafik/charts yang saya buat sesuai harapan menjadi hanya 20 baris data saja.

Seperti yang kita ketahui, google sheets secara keseluruhan maupun grafiknya saja dapat dipublish sebagai gambar ataupun grafik interaktif, sehingga bisa ditempel secara iframe pada website seperti pada grafik paling atas tulisan saya ini.

Bagaimana ? Mudah bukan ? Secara default google yang memberikan fasilitas secara gratis ini, mengatur refresh rate tiap 5 menit untuk meng-update tampilan grafiknya. Jadi kendalanya grafik tidak terlalu realtime tapi cukup menggembirakan bagi saya yang pecinta gratisan...hehehehe..

Read More

Membuat SMS Gateway Lucu Dengan SIM800L

 

Sudah lama sekali saya tidak membahas mengenai SMS gateway menggunakan modul sim800, salah satu alasannya mungkin karena ada pemblokiran IMEI dari pemerintah yang menyebabkan beberapa modem menjadi "reject" karena saat diberi AT command "AT+CREG?" balasannya "CREG :0,2" yang artinya reject dari netwoknya. Namun jangan khawatir karena beberapa trik yang dibagikan para penggiat modem simcom ada yg memang cukup jitu, dimana salah satu langkah berikut dapat dilakukan sebelum kamu membuang modem simcom kamu:

1. Pastikan tegangan VCC sesuai yaitu di 3.5-4.2 volt yang merupakan tegangan normal baterai lithium 18650. Jadi jika power supply kamu diatas itu tegangannya maka gunakanlah modul stepdown atau gunakan baterai lithium 18650 + chargernya. Ikuti salah satu setup hardware dibawah :

2. Jika menggunakan modul sim808 atau sim900 yang berupa evaluation board dan sudah ada regulator stepdown, maka pastikan power supply yg masuk ke arduino uno (jika menggandeng 5 voltnya sebagai input power) atau ke modul EV board harus menggunakan adaptor yg amperenya tinggi diatas 1.5A dan diusahakan voltase  adaptor 7.5 volt keatas. Saya menemukan dua kali seperti ini kasus dimana ketika dikasi input tegangan 5 volt modem sim808 saya auto standby / restart saat melakukan registrasi ke network (hanya kedip 4 x saja).

3. Jika memang IMEI dari modem kamu terblok oleh operator, maka langkah terakhir adalah merubah imei dengan perintah "AT+SIMEI=nomer imei baru" . Dimana bisa dapat imei baru ? Ya cari aja hp lawas yang tidak terpakai dan gunakan saja IMEI nya. Saya sukses merubah imei dari sim800L dan jangan sekali kali menghidupkan hp lawas tadi agar server CEIR dari operator seluler tidak mendeteksi fraud imei.

Dan ketika gembira mendapatkan LED modem berkedip per 0.5 detik, atau ketika dicoba "AT+COPS" dibalas "+COPS:0,0,"Indosat" " , maka kamu bisa mencoba script berikut untuk mengirim sms (pastikan pulsanya ada ya !).

#include <SoftwareSerial.h>

#define TX_PIN 8
#define RX_PIN 7

SoftwareSerial serialSIM800(TX_PIN, RX_PIN);

void setup() {
 Serial.begin(9600); //HW Serial Monitor
 while(!Serial);

 Serial.println("Inisialisasi modul SIM800L");
 serialSIM800.begin(9600);
 delay(1000);

 Serial.println("Kirim SMS...");

 //Set mode teks untuk pengiriman sms
 serialSIM800.write("AT+CMGF=1\r\n");
 delay(1000);


//Mulai mengirim Sms ganti nomer tujuan kamu
 serialSIM800.write("AT+CMGS=\"081234567890\"\r\n");
 delay(1000);
 serialSIM800.write("System ready");
 delay(1000);
 serialSIM800.write((char)26); //CTRL-Z
 delay(1000);
 Serial.println("SMS Terkirim!");
}

void loop() {

}

  

Mari kita ingat kembali sekitar 11 tahun lalu saya membagi script untuk melakukan kontrol ke mikrokontroller yang dikirimkan melalui SMS, bisa dibaca disini : https://www.aisi555.com/2013/05/sms-kontrol-mengirim-perintah-ke-micro.html , dan perintah AT commnd yang penting adalah :

AT+CMGF=1  : Untuk merubah ke mode SMS teks

AT+CNMI=2,2 : Untuk merubah sms mode flash sehingga teks bisa langsung diparsing

+CMT :"+628155555555","11/10/01,12 :30 :00+00",
pesan sms disini

AT+CPMS =?  : ini bisa diubah untuk memilih penyimpanan sms, lakukan di luar koding

AT+CMGD=1,4 : Delete semua sms agar tidak gagal sms yg baru masuk

 

Tujuan saya pada tulisan ini adalah untuk membuat semacam gateway sms humor yang akan kemudian dicoba didepan kelas mikrokontroler di prodi teknik listrik vokasi Unesa Surabaya. Jadi para mahasiswa akan mengirim sms nama mereka ke nomer sim808 yang saya pakai untuk kemudian di balas berupa humor bapack-bapack yang lumayan garing namun seru.

Bagaimana scriptnya ? Ini lengkapnya :

#include <SoftwareSerial.h>
#include <avr/pgmspace.h>  // untuk menghemat RAM gunakan PROGMEM

SoftwareSerial gsm(2, 3);  // RX, TX pins ke modem
String message = "";
String senderNumber = "";  // variabel nomer yang akan dibalas
bool newMessage = false;   // Flag ada pesan baru

// jokes bapak bapak disimpan di PROGMEM
const char joke1[] PROGMEM = "Kenapa ayam nyebrang jalan? Karena mau ke seberang!";
const char joke2[] PROGMEM = "Kenapa gajah bawa koper? Karena mau pergi liburan!";
const char joke3[] PROGMEM = "Kenapa Indonesia panas banget ya? Padahal negara ASEAN.";
const char joke4[] PROGMEM = "Uang 100 ribu jika dilempar bakal jadi apa? Jadi rebutan.";
const char joke5[] PROGMEM = "Apa yang lebih besar dari dinosaurus? Hutan tempat mereka tinggal.";
const char joke6[] PROGMEM = "Huruf-huruf apa yang sering kedinginan? Huruf B karena ada di tengah-tengah AC.";
const char joke7[] PROGMEM = "Kentang apa yang bisa bikin bayi ketawa? Kentang-tingtung-tingtang-tingtungtang.";
const char joke8[] PROGMEM = "Kesenian apa yang sering dilakukan nasabah bank? Tari tunai.";
const char joke9[] PROGMEM = "Sapi apa yang larinya cepat? Sapida motor.";
const char joke10[] PROGMEM = "Monyet apa yang bikin sebel? Monyetel tivi nggak ada remote.";
const char joke11[] PROGMEM = "Sepeda apa yang tak bisa dicat? Sepeda hilang.";

const char* const jokes[] PROGMEM = {joke1, joke2, joke3, joke4, joke5, joke6, joke7, joke8, joke9, joke10, joke11};  // Array of joke pointers

void setup() {
  gsm.begin(9600);  // Start GSM communication
  Serial.begin(9600);  // For serial monitor
  delay(1000);
  Serial.println("Test GSM Modem Server for UNESA");
  // Initialize GSM modem
  gsm.println("ATE1");
  delay(1000);
  gsm.println("AT+CMGF=1");  // Set text mode
  delay(1000);
  gsm.println("AT+CNMI=2,2");  // Sms langsung baca
  delay(1000);
  gsm.println("AT+CMGD=31,4");  // Hapus sms
  delay(1000); 

}

void loop() {
  if (gsm.available()) {
    char c = gsm.read();
    message += c;

    if (c == '\n') {  // End of a line
      Serial.print("Received: ");
      Serial.println(message);

      // Check for SMS header (+CMT) to know it's an incoming message
      if (message.indexOf("+CMT") != -1) {
        senderNumber = extractPhoneNumber(message);  // Extract sender's number
        newMessage = true;  // Set flag indicating the next line will be the message body
      } 
      else if (newMessage && message.length() > 1) {  // Process the next line after +CMT as the message body
        String studentName = message;
        studentName.trim();  // Remove any trailing spaces or newlines

        // Send greeting with a random joke
        String reply = createReply(studentName);
        sendSMS(senderNumber, reply);  // Use senderNumber extracted earlier
        newMessage = false;  // Reset flag after sending the SMS
      }

      message = "";  // Clear the message for the next line
    }
  }
}

// Extract phone number from the +CMT line
String extractPhoneNumber(String msg) {
  int startIndex = msg.indexOf("\"") + 1;
  int endIndex = msg.indexOf("\"", startIndex);
  return msg.substring(startIndex, endIndex);
}

// Create the reply message with a greeting and a random joke
String createReply(String name) {
  String greeting = "Halo " + name + ", ";

  // Generate a random index and fetch the joke from PROGMEM
  int randomIndex = random(0, 11);  
  char joke[100];  // Create a buffer to store the joke
  strcpy_P(joke, (char*)pgm_read_word(&(jokes[randomIndex])));  // Read the joke from PROGMEM
  
  return greeting + String(joke);  // Combine greeting with joke
}

// Function to send an SMS
void sendSMS(String phoneNumber, String message) {
  gsm.println("AT+CMGS=\"" + phoneNumber + "\"\r");  // Send the AT command for the recipient's number
  delay(100);
  gsm.print(message);  // Send the SMS body
  delay(100);
  gsm.write(26);  // Send Ctrl+Z to end the SMS
  delay(500);
}

BREAKDOWN :

Yang paling penting adalah meng-extract nomer pengirim dan nama pengirim SMS saat ada pesan masuk dari uart modem berupa string "+CMT " :

if (gsm.available()) {
    char c = gsm.read();
    message += c;

    if (c == '\n') {  // End of a line
      Serial.print("Received: ");
      Serial.println(message);

      // Check for SMS header (+CMT) to know it's an incoming message
      if (message.indexOf("+CMT") != -1) {
        senderNumber = extractPhoneNumber(message);  // Extract sender's number
        newMessage = true;  // Set flag indicating the next line will be the message body
      } 
      else if (newMessage && message.length() > 1) {  // Process the next line after +CMT as the message body
        String studentName = message;
        studentName.trim();  // Remove any trailing spaces or newlines

        // Send greeting with a random joke
        String reply = createReply(studentName);
        sendSMS(senderNumber, reply);  // Use senderNumber extracted earlier
        newMessage = false;  // Reset flag after sending the SMS
      }

      message = "";  // Clear the message for the next line
    }
  }

Ekstraksinya ada di function ini :

// Extract phone number from the +CMT line
String extractPhoneNumber(String msg) {
  int startIndex = msg.indexOf("\"") + 1;
  int endIndex = msg.indexOf("\"", startIndex);
  return msg.substring(startIndex, endIndex);
}

Selanjutnya adalah pemilihan jokes bapack-bapack secara random serta ditambahkan nama pengirim. Disini dapat dilihat terdapat perintah random dan diarahkan ke array jokes[] di PROGMEM

// Create the reply message with a greeting and a random joke
String createReply(String name) {
  String greeting = "Halo " + name + ", ";

  // Generate a random index and fetch the joke from PROGMEM
  int randomIndex = random(0, 11);  
  char joke[100];  // Create a buffer to store the joke
  strcpy_P(joke, (char*)pgm_read_word(&(jokes[randomIndex])));  // Read the joke from PROGMEM
  
  return greeting + String(joke);  // Combine greeting with joke
}

Lalu kemudian SMS dikirim kembali.

// Function to send an SMS
void sendSMS(String phoneNumber, String message) {
  gsm.println("AT+CMGS=\"" + phoneNumber + "\"\r");  // Send the AT command for the recipient's number
  delay(100);
  gsm.print(message);  // Send the SMS body
  delay(100);
  gsm.write(26);  // Send Ctrl+Z to end the SMS
  delay(500);
}

Dan hasilnya bisa dilihat pada gambar yang paling atas. SMS gateway seperti ini dulunya banyak digunakan untuk server penjual pulsa dimana pada saat pembelian pulsa maka dikirmkan kode-kode pulsa melalui sms ke nomer gatewaynya, dan kalau kalian sempat melihat voting indonesian idol jadul dibawah tahun 2010an maka votingnya dilakukan menggunakan sms gateway seperti penjelasan saya diatas.

Read More

[Modbus] Menampilkan Sensor Suhu Infra Red ke Matrix P10

 

Sambungan dari praktek membaca sensor suhu infra red RS-WD-HW-N01 yang saya bahas sebelumnya disini , saya akan ajarkan bagaimana menampilkan suhunya di dot matrix display P10. Display dot matrix ini paling umum digunakan di layar sekolah, toko, masjid dll, ini sangat banyak yang membahas di blog maupun youtube, dengan harga yang sangat murah (menyebabkan 10 tahun lalu saya berhenti jadi pengrajin display led matrix), namun kali ini kebetulan ada proyek dan akan saya bagi ilmunya secara perlahan.

PINOUT 

Pinoutnya berupa header 2x8 dan beberapa seller online shop diluar sana menjual header converter ke arduino uno seperti gambar diatas. Jika ingin buat sendiri tentunya tidak akan menjadi kesulitan. Untuk tegangan 5 volt sebaiknya diberikan terpisah dari arduino dengan adaptor 5v yang mempunyai ampere lebih tinggi.

LIBRARY

Library asli dibuat oleh produsen aslinya yaitu FREETRONICS dan dapat di unduh disini. Pemilihan portnya berbasiskan port SPI dimana akan memanfaatkan 2 pin MOSI (13) dan SCK (11). Sedangkan pemilihan pin OE (output enable) harus berhubungan dengan timer1 sehingga kakinya jangan dirubah dari nomer 9.

Untuk menambahkan font yang lebih keren, beberapa pengembang elektronika mikrokontroller di Indonesia berkreasi dengan library DMD3 yang bisa di googling sendiri. 

 SCRIPT 

Saya bagi aja langsung dan semoga bermanfaat untuk belajar kalian maupun tugas di sekolah/kampus.

/*      Sensor Suhu Infra merah
       Tampilan ke Led Matrix P10   
	type : RS-WD-HW-N01 RS485
	www.aisi555.com
	ahocool@gmail.com
*/

#include "BIG7SEGMENT.h"
#include "DMD3.h"
#include "DejaVuSans9.h"
#include "bmz9.h"
#include "bmz6x7.h"

#include <SoftwareSerial.h>
SoftwareSerial mod(12, 10); // RX (A) , TX (B) ke rs485 sensor 


DMD3 display (1,1);


byte baca[] = {0x01, 0x03, 0x00, 0x00, 0x00, 0x01, 0x84, 0x0A};//perintah baca suhu


byte bufferDataModbus[18];
byte *ptr;

int incomingByte ;

int suhune, puluhan, satuan;

bool terima = false;
unsigned long previousMillis = 0;


char dmdBuff1[10]; //Suhu Digit Depan koma
char dmdBuff2[10]; //belakang koma


void scan()
{
    display.refresh();
}

void setup() {
  Serial.begin(9600);
  Serial.println(F("Sensor infra red ke p10"));
  Serial.println(F("http://www.aisi555.com"));
  Serial.println();
 
  mod.begin(4800);
  ptr = bufferDataModbus;

    Timer1.initialize(1350);
    Timer1.attachInterrupt(scan);
    Timer1.pwm(9,255);
 
}

void loop() {
 unsigned long currentMillis = millis();
 
  if(currentMillis - previousMillis >= 5000) {
    // timer baca sensor tiap 5 detik 
    previousMillis = currentMillis;   
    //kirim perintah ke modbus baca suhu
   mod.write(baca, sizeof(baca));

   
   
    }

  //check modbus timeout
  long millisResponModbus = millis() + 1000;
  while (!mod.available())
  {
    if (millisResponModbus < millis())
    {
      break;//timeout
    }
  }
 
 // baca data serial yang masuk dari modbus lalu simpan pada pointer
  while (mod.available())
  { 
    byte b = mod.read();
    *ptr++ = b;
    Serial.print("0x");
    Serial.print(String(b, HEX));
    Serial.print(" ");
    delay(2);
    terima = true;
  }


if (terima){
	ptr = bufferDataModbus;

	suhune = (ptr[3] *256) + ptr[4];
	puluhan = suhune / 10;
	satuan = suhune % 10;

	Serial.print("Suhu = ");
	Serial.print(puluhan);
	Serial.print(",");
	Serial.print(satuan);
	Serial.println(" Celcius");

	memset(bufferDataModbus, 0x00, sizeof(bufferDataModbus));
	terima =false;

    display.clear();

    //tulis suhu ke p10
    display.setFont(BIG7SEGMENT);
    sprintf(dmdBuff1, "%.2d", puluhan);
    sprintf(dmdBuff2, "%.1d", satuan);

    display.drawText(0, 0, dmdBuff1);
    display.setFont(bmz9);
    display.drawText(26, -1, "C");
    display.drawRect(22,1,24,3,1);

    display.setFont(bmz6x7);
    display.drawRect(22,13,23,14,1);
    display.drawText(25, 8 , dmdBuff2);
}


}

Read More

[Modbus] Membaca Sensor Suhu RS-WD-HW-N01 RS485 - Arduino

 

Sebagai pembuka saya ingin berbagi bahwa sensor suhu inframerah memiliki beberapa kekurangan yang perlu dipertimbangkan:

1. **Akurasi terbatas**: Akurasi sensor suhu inframerah dapat dipengaruhi oleh berbagai faktor seperti emisivitas objek yang diukur, suhu lingkungan, kelembaban, dan jarak sensor dari objek. Hal ini dapat mengakibatkan pembacaan yang kurang tepat dibandingkan dengan sensor suhu kontak.

2. **Efek permukaan**: Sensor suhu inframerah mengukur suhu permukaan objek. Hal ini dapat menjadi kelemahan ketika berurusan dengan material dengan konduktivitas termal rendah atau permukaan yang tidak merata dalam suhu. Misalnya, permukaan yang mengkilap atau reflektif dapat memantulkan radiasi inframerah lingkungan, menyebabkan pembacaan yang tidak akurat.

3. **Rentang terbatas**: Beberapa sensor suhu inframerah memiliki rentang pengukuran yang terbatas, yang mungkin tidak sesuai untuk semua aplikasi. Sebagai contoh, beberapa sensor mungkin tidak dapat mengukur suhu yang sangat tinggi atau rendah dengan akurat.

4. **Waktu respons**: Sensor suhu inframerah mungkin memiliki waktu respons yang lebih lambat dibandingkan dengan sensor suhu kontak, terutama ketika mengukur suhu yang berubah dengan cepat atau objek yang bergerak.

5. **Interferensi lingkungan**: Faktor lingkungan seperti asap, debu, atau partikel lainnya di udara dapat mengganggu pengukuran suhu inframerah, menyebabkan ketidakakuratan.

6. **Biaya**: Sensor suhu inframerah dapat lebih mahal dibandingkan dengan sensor suhu kontak, terutama untuk model presisi tinggi atau yang memiliki fitur canggih.

7. **Kalibrasi**: Kalibrasi berkala diperlukan untuk menjaga akurasi sensor suhu inframerah. Hal ini membutuhkan peralatan dan keahlian khusus, menambah biaya dan kompleksitas penggunaan sensor tersebut.

8. **Kedalaman penetrasi terbatas**: Radiasi inframerah hanya dapat menembus permukaan objek yang diukur sampai kedalaman tertentu. Hal ini dapat menjadi keterbatasan ketika mengukur suhu material tebal atau tidak tembus pandang.

Meskipun memiliki kelemahan-kelemahan ini, sensor suhu inframerah tetap banyak digunakan dalam berbagai industri karena sifat non-kontaknya, kemudahan penggunaan, dan kecocokannya untuk beberapa aplikasi tertentu.

Praktek kita kali ini menggunakan TTL to RS485 agar data modbus dari sensor suhu infra red (bisa baca dulu disini untuk belajar cara akses sensor ini), dapat diubah level tegangan nya. Dan beberapa tulisan saya mengenai Modbus telah membahas juga namun kebetulan sekali ini adalah kali pertama saya membaca alat modbus menggunakan arduino uno sebagai master. Sebelumnya saya menggunakan esp8266 sebagai master modbus IOT dan arduino micro sebagai slave modbus, bisa dibaca disini dan disini .

Prinsip parsing data modbus pada pembahasan saya terdahulu tahun 2020 (jaman pandemi) seperti script berikut ini :

void loop()
{

unsigned long currentMillis = millis();
 
  if(currentMillis - previousMillis >= 5000) {
    // timer baca dht11 tiap 5 detik 
    previousMillis = currentMillis;   
    //kirim perintah ke modbus baca dht 11
   mod.write(humitemp, sizeof(humitemp));
    
    }

  //check modbus timeout
  long millisResponModbus = millis() + 1000;
  while (!mod.available())
  {
    if (millisResponModbus < millis())
    {
      break;//timeout
    }
  }
 
 // baca data serial yang masuk dari modbus lalu simpan pada pointer
  while (mod.available())
  {
    byte b = mod.read();
    *ptr++ = b;
    Serial.print("0x");
    Serial.print(String(b, HEX));
    Serial.print(" ");
    delay(2);

  }

  //proses komparasi data yg masuk (DHT11) dengan array jawaban lalu parsing
  if (memcmp(bufferDataModbus, dhtOK, sizeof(dhtOK)) == 0) {
  ptr = bufferDataModbus;
  Serial.println("");
  Serial.print(F("SUHU :"));
  Serial.print(ptr[4]); //alamat byte ke 4
  Serial.print(F(","));
  Serial.print(ptr[6]); //alamat byte ke 6
  Serial.print(F(" C HUMI :"));
  Serial.print(ptr[8]); //alamat byte ke 8
  Serial.println(" %");
  memset(bufferDataModbus, 0x00, sizeof(bufferDataModbus));
 }


}

Jadi script diatas dulu itu akan menunggu membaca data OK berdasarkan Check Sum / CRC  modbus 16bit. Namun sepertinya itu bisa diabaikan karena hampir error jarang sekali terjadi. Jadi untuk membaca sensor suhu RS-WD-HW-N01 RS485, kira kira scriptnya seperti berikut :

/* Cara baca Sensor Suhu Infra merah
    type : RS-WD-HW-N01 RS485
	www.aisi555.com
	ahocool@gmail.com
*/

#include <SoftwareSerial.h>

SoftwareSerial mod(12, 10); // RX, TX ke rs485

//perintah baca suhu, baca penjelasan di blog
byte baca[] = {0x01, 0x03, 0x00, 0x00, 0x00, 0x01, 0x84, 0x0A};


byte bufferDataModbus[10];
byte *ptr;

int incomingByte ;

int suhune, puluhan, satuan;

bool terima = false;
unsigned long previousMillis = 0;

void setup() {
  Serial.begin(9600);
  Serial.println(F("Testing Sensor Infra Ke Serial"));
  Serial.println(F("http://www.aisi555.com"));
  Serial.println();
  
  //baud rate default 4800
  mod.begin(4800);
  ptr = bufferDataModbus;
 
}

void loop() {
 unsigned long currentMillis = millis();
 
  if(currentMillis - previousMillis >= 5000) {
    // timer baca sensor tiap 5 detik 
    previousMillis = currentMillis;   
    //kirim perintah ke modbus baca sensor
   mod.write(baca, sizeof(baca));
    
    }

  //check modbus timeout
  long millisResponModbus = millis() + 1000;
  while (!mod.available())
  {
    if (millisResponModbus < millis())
    {
      break;//timeout
    }
  }
 
 // baca data serial yang masuk dari modbus lalu simpan pada pointer
  while (mod.available())
  {
    byte b = mod.read();
    *ptr++ = b;
    Serial.print("0x");
    Serial.print(String(b, HEX));
    Serial.print(" ");
    delay(1);
    terima = true;
  }

//parsing data suhu dan tampilkan di serial debug

	if (terima){
		ptr = bufferDataModbus;

		suhune = (ptr[3] *256) + ptr[4];
		puluhan = suhune / 10;
		satuan = suhune % 10;

		Serial.print("Suhu = ");
		Serial.print(puluhan);
		Serial.print(",");
		Serial.print(satuan);
		Serial.println(" Celcius");

		memset(bufferDataModbus, 0x00, sizeof(bufferDataModbus));
		terima =false;
		}


}

Hasil dari tangkapan layar debug seperti ini :

Data suhu yang akan dibaca adalah data ke-4 (0x1) dan data ke-5 (0x3E). Data lainnya bisa diabaikan, sehingga rumus parsing saya dilakukan dengan script berikut:

	if (terima){
		ptr = bufferDataModbus; // pindahkan data
                //ini rumus sederhana untuk merubah 2byte modbus jadi desimal
		suhune = (ptr[3] *256) + ptr[4]; //pointer memori mulai dari nol
		puluhan = suhune / 10;
		satuan = suhune % 10;

		Serial.print("Suhu = ");
		Serial.print(puluhan);
		Serial.print(",");
		Serial.print(satuan);
		Serial.println(" Celcius");
               //bersihkan memori
		memset(bufferDataModbus, 0x00, sizeof(bufferDataModbus));
		terima =false;
		}

Sehingga secara gampangannya , 0x01 merupakan  High Byte sehingga dapat dikalikan 256 (desimal) untuk mendapatkan nilai desimal High Byte, sedangkan 0x3E (Low Byte) bernilai  desimal 62, dan selanjutnya tinggal ditambahkan saja yaitu 256 + 62 =  318. Ini cocok hasilnya dengan hexa 0x13E. Sebenernya ada cara lebih "elegan" yaitu dengan geser byte ke kiri, namun saya yakin pembaca akan tambah bingung.

Read More

[Tutorial] Sensor Suhu Ds18b20 dan output ke display oled

 

Pada beberapa tulisan di blog ini telah sering dibahas mengenai sensor suhu dasar, baik yang paling sederhana LM35 dan yang lumayan cukup sering dipakai untuk sensor IOT yaitu DHT11. Namun untuk pengukuran yang lebih akurat dan mengakomodir suhu negatif, maka kali ini saya pilihkan sensor suhu digital DS18B20. Secara umum rangkaian DS18B20 memerlukan 3 pin dan sebuah resistor pull up data bernilai 4,7K ohm. Praktek kali ini dilakukan bersama mahasiswa teknik listrik vokasi unesa angkatan 2022.

Untuk dapat menjalankan sensor ini pada arduino atau esp8266, library yang perlu di install pada sketch arduino yaitu One Wire dan Dallas Temperature. Perhatikan penjelasan script dasar berikut ini untuk mendapatkan pembacaan suhu yang tepat.

#include <OneWire.h>
#include <DallasTemperature.h>

// Sensor data ke digital pin 4, sesuaikan yg dipakai
#define ONE_WIRE_BUS 4

// inisialisasi nama library one wire
OneWire oneWire(ONE_WIRE_BUS);

// menghubungkan library onewire vs Dallas Temperature 
DallasTemperature sensors(&oneWire);

void setup(void)
{
  // Start serial baud 9600
  Serial.begin(9600);
  // memulai ibrary library
  sensors.begin();
}

void loop(void){ 
  // Panggil pembacaan sensor pada bus one wire
  sensors.requestTemperatures(); 
  //tulis ke serial monitor
  Serial.print("Celsius temperature: ");
  // kasi index 0 karena cuman 1 sensor, bisa untuk banyak sensor
  Serial.print(sensors.getTempCByIndex(0)); 
  Serial.print(" - Fahrenheit temperature: ");
  Serial.println(sensors.getTempFByIndex(0));
  delay(1000);
}

Dan jika rangkaian sudah benar maka hasilnya seperti berikut ini :

Catatan jika menggunakan wemos atau nodemcu, pin yang digunakan disesuaikan dengan tulisan pin pada board, namun asal board yang digunakan sesuai. Perhatikan gambar dibawah ini :

Jadi jika library boardnya sesuai maka cukup mengikuti penamaan pada board yg dipakai, seperti contoh dibawah ini :

 

// Sensor data ke digital pin D4, sesuaikan yg dipakai
#define ONE_WIRE_BUS D4

-  Display Ke OLED 

Layar oled yang kita gunakan adalah OLED SSD12306 dengan lebar layar 128x64 pixel. 

Pin dari OLED ini berbasis I2C 3.3 volt, sehingga VCC/VDD jangan sampai salah colok harus ke pin 3.3 volt pada wemos kamu. I2C merupakan komunikasi data 2 kabel dengan SCK (serial clock) dan SDA (serial data), dimana pada wemos pin SCK = D1 , sedangkan SDA = D2. Untuk mencoba melakukan testing terhadap display oled kamu bisa menggunakan script example pada Library Adafruit_SSD1306 .

catatan: Pada example terdapat kesalahan address dari oled yang dijual dipasaran ( 128 x 64 ) yang seharusnya 0x3C

#define OLED_RESET     -1 // Reset pin # (or -1 if sharing Arduino reset pin)
#define SCREEN_ADDRESS 0x3C ///< See datasheet for Address; 0x3D for 128x64, 0x3C for 128x32
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

Lalu mari kita gabungkan 2 koding diatas untuk menampilkan pengukuran sensor suhu DS12B20 pada OLED.

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <OneWire.h>
#include <DallasTemperature.h>


#define SCREEN_WIDTH 128 // display display width, in pixels
#define SCREEN_HEIGHT 64 // display display height, in pixels

#define SENSOR_PIN D4   // pin sensor DS18B20
#define BUZZER_PIN D5   // pin buzzer

#define display_RESET     -1 // Reset pin 
#define SCREEN_ADDRESS 0x3C ///address i2c oled 
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, display_RESET);

OneWire oneWire(SENSOR_PIN);         // setup a oneWire 
DallasTemperature tempSensor(&oneWire); // pass oneWire 



unsigned long previousMillis = 0;

String tempString,tempString1;
float batas = 35;     // batas suhu biar alarm
float tempCelsius;


void setup() {
  Serial.begin(9600);
  pinMode(BUZZER_PIN,OUTPUT);
  digitalWrite(BUZZER_PIN,LOW);

  // initialize display display with address 0x3C for 128x64
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    while (true);
  }

  delay(2000);         // wait for initializing
  display.clearDisplay(); // clear display

  display.setTextSize(1);          // text size
  display.setTextColor(WHITE);     // text color
  
  displayDisplayCenter("Teknik Listrik", 4);
  displayDisplayCenter("Vokasi Unesa 2023",56);

  display.setTextSize(2);
  display.setCursor(0, 32);        // position to display

  tempSensor.begin();     // initialize the sensor
  tempString.reserve(10); // to avoid fragmenting memory when using String


  

  
}

void loop() {
  tempSensor.requestTemperatures();             // send the command to get temperatures
  tempCelsius = tempSensor.getTempCByIndex(0);  // read temperature in Celsius

  
  tempString  = String(tempCelsius, 2); // two decimal places
  tempString += (char)247;
  tempString += "C";
  
  //biar ketumpuk hitam dulu jika suhu nya berubah
  if(tempString != tempString1)
  {
  display.setTextColor(BLACK);
  displayDisplayCenter(tempString1,28);
  }
  
  tempString1= tempString; 
  Serial.println(tempString); // print the temperature in Celsius to Serial Monitor
  
  //lanjut tulis warna putih
  display.setTextColor(WHITE);
  displayDisplayCenter(tempString,28);


  if( tempCelsius >= batas)  //cek alarm vs buzzer
   {

    digitalWrite(BUZZER_PIN,HIGH);
    delay(200);
    digitalWrite(BUZZER_PIN,LOW);
    delay(50);
   }
  
  else digitalWrite(BUZZER_PIN,LOW);
   
}

//function agar tulisan rata tengah (center)

void displayDisplayCenter(String text, int posisi) {
  int16_t x1;
  int16_t y1;
  uint16_t width;
  uint16_t height;

  display.getTextBounds(text, 0, 0, &x1, &y1, &width, &height);

  display.setCursor((SCREEN_WIDTH - width) / 2, posisi);
  display.println(text); // text to display
  display.display();
}

Dan hasilnya menjadi keren seperti ini :

Read More

[Tutorial] Dasar Input - Output Pada Mikrokontroler

Pada umumnya terdapat 2 jenis input output yang terlihat paling "sederhana" dan paling sering dibahas pada sebuah sistem mikrokontroler AVR, arduino maupun ESP 8266. Dari list dibawah ini, nomer 1 dan 2 akan kita praktekkan pada tulisan blog kali ini, bersama dengan adik - adik mahasiswa di jurusan teknik listrik vokasi unesa Surabaya. 

Jenis Input Output :

1. Digital Pin
2. Analog Pin
3. PWM
4. Serial
5. I2C
6. SPI

- DIGITAL PIN

Digital pin ini merupakan hal yang paling dasar yang pertama kali harus dipraktekkan ketika memulai mikrokontroler sekelas arduino. Coba pembaca buka sketch dan akan menemukan example yang bernama "blink" yang merupakan coding untuk menyalakan dan mematikan LED internal pada bord arduino ( jenis apapun ) yang umumnya berada pada pin 13.

 void setup() {

  // inisialisasi digital pin LED_BUILTIN sebagai output.

  pinMode(LED_BUILTIN, OUTPUT);

}

//the loop function muter terus

void loop() {

  digitalWrite(LED_BUILTIN, HIGH);  // HIGH = Nyala

  delay(1000);                      // Tunggu 1 detik

  digitalWrite(LED_BUILTIN, LOW);   // LOW = Mati

  delay(1000);                      // Tunggu 1 detik

}

Dan kemudian perhatikan gambar ekuivalen dari sebuah Bit Input Output pada mikrokontroler, melalui tombol sebagai Input dan Led sebagai output .

Saya ingin membuat penekanan tombol switch tactile bereaksi terhadap led, dan tidak ingin menjadi on off seperti saklar biasa. Jadi saat tombol (aktif low / pull up) maka akan merubah status dari led nyala atau mati. Perhatikan script berikut dan akan saya bahas per bagian.

const int buttonPin = 9;     // pin push button

const int ledPin =  13;      // pin LED

int buttonState = 0;         // variable status tombol

bool ledstate;

void setup() {

  //Pin LED sebagai output

  pinMode(ledPin, OUTPUT);

  // tombol sebagai intput

  pinMode(buttonPin, INPUT);

   

  //status awal led mati 

  ledstate = false;

  digitalWrite(ledPin, LOW);

  Serial.begin(9600); //agar bisa dilihat pada terminal

}

void loop() {

  // baca status tombol

  buttonState = digitalRead(buttonPin);

  // cek status tombol High atau Low

  if (buttonState == HIGH) {

    

    //nyalakan led dan ubah status led 

    if ( !ledstate){

      digitalWrite(ledPin, HIGH);

      ledstate =true;

      //kirim serial

      Serial.println("Kondisi led = Nyala");

     }

    //matikan led

     else {

      digitalWrite(ledPin, LOW);

      ledstate = false;

      Serial.println("Kondisi led = mati");

    }

  delay(200);

    

  } 

  

}

Dari script diatas, penjelasan perbagian  bisa dilihat pada bagian script berwarna merah, dan yang paling utama adalah proses perubahan status boolean dari led status yang akan tersimpan sesuai kondisi terakhir dari led.

    //nyalakan led dan ubah status led 

    if ( !ledstate){

      digitalWrite(ledPin, HIGH);

      ledstate =true;

      //kirim serial

      Serial.println("Kondisi led = Nyala");

     }

    //matikan led

    else {

      digitalWrite(ledPin, LOW);

      ledstate = false;

      Serial.println("Kondisi led = mati");

    }

Terdapat perintah Serial.println yang bertujuan untuk melihat kondisi led pada serial monitor yang merupakan fasilitas debuging paling utama pada sketch arduino.

Pada tulisan selanjutnya akan saya bahas input analog yang sangat bermanfaat.

Read More