[Modbus] Menampilkan Sensor Suhu Infra Red ke Matrix P10

 

Sambungan dari praktek membaca sensor suhu infra red RS-WD-HW-N01 yang saya bahas sebelumnya disini , saya akan ajarkan bagaimana menampilkan suhunya di dot matrix display P10. Display dot matrix ini paling umum digunakan di layar sekolah, toko, masjid dll, ini sangat banyak yang membahas di blog maupun youtube, dengan harga yang sangat murah (menyebabkan 10 tahun lalu saya berhenti jadi pengrajin display led matrix), namun kali ini kebetulan ada proyek dan akan saya bagi ilmunya secara perlahan.

PINOUT 

Pinoutnya berupa header 2x8 dan beberapa seller online shop diluar sana menjual header converter ke arduino uno seperti gambar diatas. Jika ingin buat sendiri tentunya tidak akan menjadi kesulitan. Untuk tegangan 5 volt sebaiknya diberikan terpisah dari arduino dengan adaptor 5v yang mempunyai ampere lebih tinggi.

LIBRARY

Library asli dibuat oleh produsen aslinya yaitu FREETRONICS dan dapat di unduh disini. Pemilihan portnya berbasiskan port SPI dimana akan memanfaatkan 2 pin MOSI (13) dan SCK (11). Sedangkan pemilihan pin OE (output enable) harus berhubungan dengan timer1 sehingga kakinya jangan dirubah dari nomer 9.

Untuk menambahkan font yang lebih keren, beberapa pengembang elektronika mikrokontroller di Indonesia berkreasi dengan library DMD3 yang bisa di googling sendiri. 

 SCRIPT 

Saya bagi aja langsung dan semoga bermanfaat untuk belajar kalian maupun tugas di sekolah/kampus.

/*      Sensor Suhu Infra merah
       Tampilan ke Led Matrix P10   
	type : RS-WD-HW-N01 RS485
	www.aisi555.com
	ahocool@gmail.com
*/

#include "BIG7SEGMENT.h"
#include "DMD3.h"
#include "DejaVuSans9.h"
#include "bmz9.h"
#include "bmz6x7.h"

#include <SoftwareSerial.h>
SoftwareSerial mod(12, 10); // RX (A) , TX (B) ke rs485 sensor 


DMD3 display (1,1);


byte baca[] = {0x01, 0x03, 0x00, 0x00, 0x00, 0x01, 0x84, 0x0A};//perintah baca suhu


byte bufferDataModbus[18];
byte *ptr;

int incomingByte ;

int suhune, puluhan, satuan;

bool terima = false;
unsigned long previousMillis = 0;


char dmdBuff1[10]; //Suhu Digit Depan koma
char dmdBuff2[10]; //belakang koma


void scan()
{
    display.refresh();
}

void setup() {
  Serial.begin(9600);
  Serial.println(F("Sensor infra red ke p10"));
  Serial.println(F("http://www.aisi555.com"));
  Serial.println();
 
  mod.begin(4800);
  ptr = bufferDataModbus;

    Timer1.initialize(1350);
    Timer1.attachInterrupt(scan);
    Timer1.pwm(9,255);
 
}

void loop() {
 unsigned long currentMillis = millis();
 
  if(currentMillis - previousMillis >= 5000) {
    // timer baca sensor tiap 5 detik 
    previousMillis = currentMillis;   
    //kirim perintah ke modbus baca suhu
   mod.write(baca, sizeof(baca));

   
   
    }

  //check modbus timeout
  long millisResponModbus = millis() + 1000;
  while (!mod.available())
  {
    if (millisResponModbus < millis())
    {
      break;//timeout
    }
  }
 
 // baca data serial yang masuk dari modbus lalu simpan pada pointer
  while (mod.available())
  { 
    byte b = mod.read();
    *ptr++ = b;
    Serial.print("0x");
    Serial.print(String(b, HEX));
    Serial.print(" ");
    delay(2);
    terima = true;
  }


if (terima){
	ptr = bufferDataModbus;

	suhune = (ptr[3] *256) + ptr[4];
	puluhan = suhune / 10;
	satuan = suhune % 10;

	Serial.print("Suhu = ");
	Serial.print(puluhan);
	Serial.print(",");
	Serial.print(satuan);
	Serial.println(" Celcius");

	memset(bufferDataModbus, 0x00, sizeof(bufferDataModbus));
	terima =false;

    display.clear();

    //tulis suhu ke p10
    display.setFont(BIG7SEGMENT);
    sprintf(dmdBuff1, "%.2d", puluhan);
    sprintf(dmdBuff2, "%.1d", satuan);

    display.drawText(0, 0, dmdBuff1);
    display.setFont(bmz9);
    display.drawText(26, -1, "C");
    display.drawRect(22,1,24,3,1);

    display.setFont(bmz6x7);
    display.drawRect(22,13,23,14,1);
    display.drawText(25, 8 , dmdBuff2);
}


}

Read More

[RTL-SDR] Perkenalan dunia radio dengan dongle usb ePro - Fitipower - FC0012

 

Tulisan saya mengenai topik radio RTL-SDR ini mungkin terkesan " kok baru sekarang ?" padahal sejak 2010an saya sudah menjadi pembaca setia di forum internet mengenai SDR, terutama di forum kaskus saat itu. Namun karena memang topiknya entah sudah bosen, wajar saja saat itu saya bekerja di vendor perangkat telco, maka hal ini hanya menjadi selingan bacaan seru melihat para kaskuser rakom berhasil membuat SDR sederhana, menggunakan sound card sebagai ADC nya dan radionya bekerja di frekuensi HF 80m band. Seru sekali saya melihatnya sampai suatu ketika saya menemukan website websdr.

WEBSDR merupakan website yang menyediakan kumpulan penghobi atau lab di kampus yang menyediakan perangkat DSR berbasis DSP/FPGA dan kemudian di share ke pengguna melalui online. Jadi saat itu ketika melihat alat DSP nya mereka canggih-canggih membuat nyali ciut, walau saya familiar dengan FPGA namun kemudian saya berpikir toh dengan klik mouse saja sudah bisa merasakan berselancar ke berbagai radio analog di seluruh dunia. Mulai dari siaran broadcast sampai ke radio milik polisi di belanda sana. Seru deh, coba aja berkunjung.

Gambar diatas bukan iklan di blog saya ya, namun memang saya ketemukan suatu ketika saya browsing dan terkejut ada yg menjual RTL-SDR dongle dengan harga lumayan tidak masuk akal. Padahal sekitar 5 tahun sebelumnya saya melihat dongle yang "asli" walau sebenarnya adalah TV tuner DVBT dijual masih cukup mahal. Ini 65 ribu bedanya apa ya ? Jika kalian penasaran saya kasi spoiler bedanya ya..

Dongle DVBT yang warna biru itu menjadi incaran saya sejak lama karena merupakan dongle bikinan realtek yang asli dan bisa dioprek menjadi penrima radi dari frekuensi 25Mhz -1700Mhz . Sedangkan yang sebenarnya yang ditawarkan oleh penjual di olshop ini adalah yang sebelah kanan, jelasnya bentuknya begini.

Larilah saya ke bagian komentar dan rating, dan ya memang ada yang puas karena murahnya tentu, dan ada yg teriak karena dianggap seller telah menipunya. Namun ada juga yang bilang kalau sesuai harga karena frekuensi responsenya dari 25-980 Mhz saja. Googling lagi dan web rtl-sdr memang memberi warning akan penipuan dongle rtl-sdr KW yang ternyata berbeda di chipset tunernya, walau sama-sama menggunakan chip DSP RTL2832U. Yang asli menggunakan tuner produk rafael micro sedangkan yg epro ini menggunakan fitipro fc0012. Keputusan saya? PENCET ORDER AJA !  

Dan datanglah barangnya lalu saya coba dengan menggunakan berbagai resource internet yang ada, dan bagi pemula saya sarankan menggunakan SDR# (sdr sharp) sebagai software sdr nya dan menginstall driver dari file yang diberikan (berbasis zadig). Saya gak akan menjelaskan lagi karena banyak sekali blog dalam maupun luar serta video youtube yang menjelaskan langkah instalasi. 

Lalu yang sangat krusial adalah pemilihan antena, dan kebetulan setahun ini saya telah bergelut dengan berbagai antena selama migrasi tv digital, dan saya colokkan aja ke dongle usb ini karena memang colokannya cocok berupa jack tv RG6. Hasilnya bagaimana ?

Tulisan pembukaan ini akan pendek saja, lain kali akan saya bagi berbagai pengalaman eksplorasi dongle ini terutama berhubungan dengan DAB (digital radio) dan DMR ( Digital Mobile Radio).

 

Read More

[Modbus] Membaca Sensor Suhu RS-WD-HW-N01 RS485 - Arduino

 

Sebagai pembuka saya ingin berbagi bahwa sensor suhu inframerah memiliki beberapa kekurangan yang perlu dipertimbangkan:

1. **Akurasi terbatas**: Akurasi sensor suhu inframerah dapat dipengaruhi oleh berbagai faktor seperti emisivitas objek yang diukur, suhu lingkungan, kelembaban, dan jarak sensor dari objek. Hal ini dapat mengakibatkan pembacaan yang kurang tepat dibandingkan dengan sensor suhu kontak.

2. **Efek permukaan**: Sensor suhu inframerah mengukur suhu permukaan objek. Hal ini dapat menjadi kelemahan ketika berurusan dengan material dengan konduktivitas termal rendah atau permukaan yang tidak merata dalam suhu. Misalnya, permukaan yang mengkilap atau reflektif dapat memantulkan radiasi inframerah lingkungan, menyebabkan pembacaan yang tidak akurat.

3. **Rentang terbatas**: Beberapa sensor suhu inframerah memiliki rentang pengukuran yang terbatas, yang mungkin tidak sesuai untuk semua aplikasi. Sebagai contoh, beberapa sensor mungkin tidak dapat mengukur suhu yang sangat tinggi atau rendah dengan akurat.

4. **Waktu respons**: Sensor suhu inframerah mungkin memiliki waktu respons yang lebih lambat dibandingkan dengan sensor suhu kontak, terutama ketika mengukur suhu yang berubah dengan cepat atau objek yang bergerak.

5. **Interferensi lingkungan**: Faktor lingkungan seperti asap, debu, atau partikel lainnya di udara dapat mengganggu pengukuran suhu inframerah, menyebabkan ketidakakuratan.

6. **Biaya**: Sensor suhu inframerah dapat lebih mahal dibandingkan dengan sensor suhu kontak, terutama untuk model presisi tinggi atau yang memiliki fitur canggih.

7. **Kalibrasi**: Kalibrasi berkala diperlukan untuk menjaga akurasi sensor suhu inframerah. Hal ini membutuhkan peralatan dan keahlian khusus, menambah biaya dan kompleksitas penggunaan sensor tersebut.

8. **Kedalaman penetrasi terbatas**: Radiasi inframerah hanya dapat menembus permukaan objek yang diukur sampai kedalaman tertentu. Hal ini dapat menjadi keterbatasan ketika mengukur suhu material tebal atau tidak tembus pandang.

Meskipun memiliki kelemahan-kelemahan ini, sensor suhu inframerah tetap banyak digunakan dalam berbagai industri karena sifat non-kontaknya, kemudahan penggunaan, dan kecocokannya untuk beberapa aplikasi tertentu.

Praktek kita kali ini menggunakan TTL to RS485 agar data modbus dari sensor suhu infra red (bisa baca dulu disini untuk belajar cara akses sensor ini), dapat diubah level tegangan nya. Dan beberapa tulisan saya mengenai Modbus telah membahas juga namun kebetulan sekali ini adalah kali pertama saya membaca alat modbus menggunakan arduino uno sebagai master. Sebelumnya saya menggunakan esp8266 sebagai master modbus IOT dan arduino micro sebagai slave modbus, bisa dibaca disini dan disini .

Prinsip parsing data modbus pada pembahasan saya terdahulu tahun 2020 (jaman pandemi) seperti script berikut ini :

void loop()
{

unsigned long currentMillis = millis();
 
  if(currentMillis - previousMillis >= 5000) {
    // timer baca dht11 tiap 5 detik 
    previousMillis = currentMillis;   
    //kirim perintah ke modbus baca dht 11
   mod.write(humitemp, sizeof(humitemp));
    
    }

  //check modbus timeout
  long millisResponModbus = millis() + 1000;
  while (!mod.available())
  {
    if (millisResponModbus < millis())
    {
      break;//timeout
    }
  }
 
 // baca data serial yang masuk dari modbus lalu simpan pada pointer
  while (mod.available())
  {
    byte b = mod.read();
    *ptr++ = b;
    Serial.print("0x");
    Serial.print(String(b, HEX));
    Serial.print(" ");
    delay(2);

  }

  //proses komparasi data yg masuk (DHT11) dengan array jawaban lalu parsing
  if (memcmp(bufferDataModbus, dhtOK, sizeof(dhtOK)) == 0) {
  ptr = bufferDataModbus;
  Serial.println("");
  Serial.print(F("SUHU :"));
  Serial.print(ptr[4]); //alamat byte ke 4
  Serial.print(F(","));
  Serial.print(ptr[6]); //alamat byte ke 6
  Serial.print(F(" C HUMI :"));
  Serial.print(ptr[8]); //alamat byte ke 8
  Serial.println(" %");
  memset(bufferDataModbus, 0x00, sizeof(bufferDataModbus));
 }


}

Jadi script diatas dulu itu akan menunggu membaca data OK berdasarkan Check Sum / CRC  modbus 16bit. Namun sepertinya itu bisa diabaikan karena hampir error jarang sekali terjadi. Jadi untuk membaca sensor suhu RS-WD-HW-N01 RS485, kira kira scriptnya seperti berikut :

/* Cara baca Sensor Suhu Infra merah
    type : RS-WD-HW-N01 RS485
	www.aisi555.com
	ahocool@gmail.com
*/

#include <SoftwareSerial.h>

SoftwareSerial mod(12, 10); // RX, TX ke rs485

//perintah baca suhu, baca penjelasan di blog
byte baca[] = {0x01, 0x03, 0x00, 0x00, 0x00, 0x01, 0x84, 0x0A};


byte bufferDataModbus[10];
byte *ptr;

int incomingByte ;

int suhune, puluhan, satuan;

bool terima = false;
unsigned long previousMillis = 0;

void setup() {
  Serial.begin(9600);
  Serial.println(F("Testing Sensor Infra Ke Serial"));
  Serial.println(F("http://www.aisi555.com"));
  Serial.println();
  
  //baud rate default 4800
  mod.begin(4800);
  ptr = bufferDataModbus;
 
}

void loop() {
 unsigned long currentMillis = millis();
 
  if(currentMillis - previousMillis >= 5000) {
    // timer baca sensor tiap 5 detik 
    previousMillis = currentMillis;   
    //kirim perintah ke modbus baca sensor
   mod.write(baca, sizeof(baca));
    
    }

  //check modbus timeout
  long millisResponModbus = millis() + 1000;
  while (!mod.available())
  {
    if (millisResponModbus < millis())
    {
      break;//timeout
    }
  }
 
 // baca data serial yang masuk dari modbus lalu simpan pada pointer
  while (mod.available())
  {
    byte b = mod.read();
    *ptr++ = b;
    Serial.print("0x");
    Serial.print(String(b, HEX));
    Serial.print(" ");
    delay(1);
    terima = true;
  }

//parsing data suhu dan tampilkan di serial debug

	if (terima){
		ptr = bufferDataModbus;

		suhune = (ptr[3] *256) + ptr[4];
		puluhan = suhune / 10;
		satuan = suhune % 10;

		Serial.print("Suhu = ");
		Serial.print(puluhan);
		Serial.print(",");
		Serial.print(satuan);
		Serial.println(" Celcius");

		memset(bufferDataModbus, 0x00, sizeof(bufferDataModbus));
		terima =false;
		}


}

Hasil dari tangkapan layar debug seperti ini :

Data suhu yang akan dibaca adalah data ke-4 (0x1) dan data ke-5 (0x3E). Data lainnya bisa diabaikan, sehingga rumus parsing saya dilakukan dengan script berikut:

	if (terima){
		ptr = bufferDataModbus; // pindahkan data
                //ini rumus sederhana untuk merubah 2byte modbus jadi desimal
		suhune = (ptr[3] *256) + ptr[4]; //pointer memori mulai dari nol
		puluhan = suhune / 10;
		satuan = suhune % 10;

		Serial.print("Suhu = ");
		Serial.print(puluhan);
		Serial.print(",");
		Serial.print(satuan);
		Serial.println(" Celcius");
               //bersihkan memori
		memset(bufferDataModbus, 0x00, sizeof(bufferDataModbus));
		terima =false;
		}

Sehingga secara gampangannya , 0x01 merupakan  High Byte sehingga dapat dikalikan 256 (desimal) untuk mendapatkan nilai desimal High Byte, sedangkan 0x3E (Low Byte) bernilai  desimal 62, dan selanjutnya tinggal ditambahkan saja yaitu 256 + 62 =  318. Ini cocok hasilnya dengan hexa 0x13E. Sebenernya ada cara lebih "elegan" yaitu dengan geser byte ke kiri, namun saya yakin pembaca akan tambah bingung.

Read More

[Modbus] Cara Membaca Sensor Suhu RS-WD-HW-N01 RS485 - PC

 

Sensor yang saya dapat kali ini merupakan request dari salah satu pembaca blog ini, yang secara kebetulan memang sangat jarang resource nya di internet. Datasheet pun didapatkan di scribd dengan beberapa kerancuan settingan dan parameter, dimana pembaca sempat beberapa kali kesal dan mengira alat converter RS-485 to USB/PC nya error. Namun saya berhasil menemukan datasheet dari alat yang sejenis (walau beda versi) berbahasa mandarin dan sukses melakukan pembacaan datanya melalui PC.

Alat ini dari produsennya shandong renke sebenarnya diharapkan dihubungkan dengan display, plc dan alarm buatan internal mereka semuanya. Sehingga ini yang menyebabkan sedikitnya resource internet yang membahas sensor ini.

Berikut ini adalah parameter yang benar dari alat ini :

• Kabel Coklat : VCC 10-30 volt (typical 24 volt)
• Kabel Hitam : GND
• Kabel Kuning : RS485 A
• Kabel Biru : RS485 B
• Baud Rate : 4800 bps (awas salah)
• Protokol : Modbus RTU
• Default ID : 1
• Range suhu :  0 -200 Celcius

Untuk melakukan pembacaan melaui PC maka perlu disiapkan berupa converter RS485 to USB dan software pembaca data modbus seperti radzio atau serial terminal yang pernah saya bahas disini. 

Untuk melakukan pembacaan data suhu, maka perintah yang diberikan adalah function code 03 (read holding register), dengan alamat memory 0000h atau 0001h. Jadi rincian kode modbusnya seperti berikut :

01 03 00 00 00 01 84 0A

01     =  Alamat device id sensor

03     =  Perintah baca holding register / function 03

00 00  = 2 byte alamat address memori (0)

00 01  = 2 byte panjang data yg diharapkan ( 1 data saja)

84 0A  = Checksum / CRC 16 modbus

Sedangkan jika data dikirmkan dengan benar, maka reply yang didapat seperti  berikut :

01 03 02 01 16 38 1A

01     =  Alamat device id sensor

03     =  Reply holding register / function 03

02     = Data suhu ber-format 2 byte 

01 16  = 2 byte data suhu

38 1A  = Checksum / CRC 16 modbus

Data yang diberikan oleh sensor suhu ini berupa hexa 2 byte yang diterjemahkan menjadi 0x116 atau desimal 278. Artinya suhu yang diukur adalah 27.8 Celcius. Dapat dilihat dari hasil capture radzio dibawah ini.

Di tulisan selanjutnya saya akan mencoba melakukan pembacaan sensor  Suhu RS-WD-HW-N01 menggunakan arduino.

Read More